एक्सेल CHOOSE समारोह

Description

वाक्यविन्यास और तर्क

उपयोग और उदाहरण

• Ex1 - मूल उपयोग: उपयोग करना CHOOSE सूची तर्क से मूल्य चुनने के लिए अकेले कार्य करें
• Ex2 - कई स्थितियों के आधार पर अलग-अलग परिणाम लौटाएँ
• Ex3 - शर्तों के आधार पर अलग-अलग परिकलित परिणाम लौटाएँ
• Ex4 - सूची से यादृच्छिक चुनें
• Ex5 - संयुक्त CHOOSE और VLOOKUP बाएं कॉलम में मान लौटाने का कार्य
• Ex6 - दी गई तारीख के आधार पर कार्यदिवस या महीना लौटाएँ
• Ex7 - आज के आधार पर अगले कार्यदिवस/सप्ताहांत तिथि पर लौटें

---

Description

RSI CHOOSE फ़ंक्शन दिए गए सूचकांक संख्या के आधार पर मूल्य तर्क की सूची से एक मान लौटाता है। उदाहरण के लिए, CHOOSE(3,”Apple”,”Peach”,”Orange”) ऑरेंज लौटाता है, इंडेक्स नंबर 3 है, और ऑरेंज फ़ंक्शन में इंडेक्स नंबर के बाद तीसरा मान है।

वाक्यविन्यास और तर्क

सूत्र वाक्यविन्यास

CHOOSE(index_num, value1, [value2], …)

तर्क

Index_num: आवश्यक। 1-254 के बीच एक संख्यात्मक मान अप्रत्यक्ष रूप से कौन सा तर्क मान चुना जाएगा। यदि Index_num 1-254 के बीच के पैमाने से बाहर है, CHOOSE रिटर्न देता है #VALUE! त्रुटि मान. यदि Index_num एक दशमलव मान है, तो सूत्र का उपयोग करने से पहले इसे पूर्ण संख्या में पूर्णांकित किया जाएगा। Value1: आवश्यक। सूत्र में पहला मान जिसे चुना जा सकता है। Value2: वैकल्पिक। दूसरा और अधिकतम 254वाँ मान जिसमें से चुनना है।

Value1, value2... संख्याएँ, पाठ, सूत्र, सेल संदर्भ या परिभाषित नाम हो सकते हैं।

प्रतिलाभ की मात्रा

RSI CHOOSE फ़ंक्शन दी गई स्थिति के आधार पर सूची से एक मान लौटाता है।

उपयोग और उदाहरण

इस भाग में, मैं इसके उपयोग को समझाने के लिए कुछ सरल लेकिन प्रतिनिधि उदाहरण सूचीबद्ध करता हूँ CHOOSE समारोह.

Ex1 - मूल उपयोग: उपयोग करना CHOOSE सूची तर्क से मूल्य चुनने के लिए अकेले कार्य करें

सूत्र 1:

=CHOOSE(3,"a","b","c","d")

रिटर्न: c, जो कि 3 के Index_num के बाद तीसरा तर्क है CHOOSE समारोह.

ध्यान दें: यदि मान टेक्स्ट है तो उसके आसपास दोहरे उद्धरण चिह्नों का उपयोग करें।

सूत्र 2:

=CHOOSE(2,A1,A2,A3,A4)

वापसी: केट, A2 का मान। चूँकि Index_num 2 है, और A2 इसमें दूसरा मान है CHOOSE समारोह.

सूत्र 3:

=CHOOSE(4,8,9,7,6)

वापसी: 6, फ़ंक्शन में चौथा सूची तर्क।

---

Ex2 - कई स्थितियों के आधार पर अलग-अलग परिणाम लौटाएँ

मान लीजिए कि आपके पास प्रत्येक उत्पाद के लिए विचलन की एक सूची है जिसे नीचे दिखाए गए स्क्रीनशॉट के अनुसार स्थितियों के आधार पर लेबल करने की आवश्यकता है।

आमतौर पर, आप संभालने के लिए IF फ़ंक्शन का उपयोग कर सकते हैं, लेकिन यहां मैं इसका उपयोग करने का तरीका बता रहा हूं CHOOSE इस समस्या को आसानी से हल करने का कार्य करें

फॉर्मूला:

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

के बारे में बताएं:

(B7>0)+(B7>1)+(B7>5): सूचकांक संख्या, बी7 2 है, जो 0 और 1 से बड़ा है लेकिन 5 से कम है, इसलिए हमें मध्यवर्ती परिणाम मिलता है:

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

जैसा कि हम जानते हैं, सत्य = 1, ग़लत = 0, इसलिए सूत्र को इस प्रकार देखा जा सकता है:

=CHOOSE(1+1+0,"Top","Middle","Bottom")

फिर

=CHOOSE(2,"Top","Middle","Bottom")

परिणाम: मध्य

---

Ex3 - शर्तों के आधार पर अलग-अलग परिकलित परिणाम लौटाएँ

मान लीजिए कि आपको नीचे दिखाए गए स्क्रीनशॉट के अनुसार राशि और कीमत के आधार पर प्रत्येक उत्पाद के लिए छूट की गणना करने की आवश्यकता है:

फॉर्मूला:

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

के बारे में बताएं:

(B8>0)+(B8>100)+(B8>200)+(B8>300): इंडेक्स_नंबर, बी8 102 है, जो 100 से बड़ा है लेकिन 201 से कम है, इसलिए इस भाग में, यह परिणाम दिखाता है:

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

फिर

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: जिन मूल्यों में से चयन करना है, छूट कीमत * राशि * छूट प्रतिशत के बराबर है, क्योंकि यहां सूचकांक संख्या 2 है, यह B8*C8*0.2 चुनता है

रिटर्न: 102*2*0.2=40.8

---

Ex4 - सूची से यादृच्छिक चुनें

एक्सेल में, कभी-कभी, आपको किसी दी गई सूची से बेतरतीब ढंग से एक मान चुनने की आवश्यकता हो सकती है CHOOSE फ़ंक्शन इस कार्य को हल कर सकता है.

किसी सूची से यादृच्छिक रूप से एक मान चुनें:

फॉर्मूला:

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

के बारे में बताएं:

RANDBETWEEN(1,5): Index_num, यादृच्छिक रूप से 1 से 5 के बीच संख्या प्राप्त करें

$D$2,$D$3,$D$4,$D$5,$D$6: उन मानों की सूची जिनमें से चयन करना है

---

Ex5 - संयुक्त CHOOSE और VLOOKUP बाएं कॉलम में मान लौटाने का कार्य

आम तौर पर, हम VLOOKUP फ़ंक्शन का उपयोग करते हैं =VLOOKUP (value, table, col_index, [range_lookup]) तालिका श्रेणी से दिए गए मान के आधार पर मान वापस करने के लिए। लेकिन के साथ VLOOKUP फ़ंक्शन, यह एक त्रुटि मान लौटाएगा जबकि रिटर्न कॉलम लुकअप कॉलम के बाईं ओर है जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है:

इस स्थिति में, आप इन्हें संयोजित कर सकते हैं CHOOSE समस्या को हल करने के लिए VLOOKUP फ़ंक्शन के साथ कार्य करें।

फॉर्मूला:

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

के बारे में बताएं:

CHOOSE({1,2},B1:B7,A1:A7): VLOOKUP फ़ंक्शन में टेबल_रेंज तर्क के रूप में। {1,2} का अर्थ है VLOOKUP फ़ंक्शन में col_num तर्क के आधार पर 1 या 2 को Index_num तर्क के रूप में प्रदर्शित करना। यहां, VLOOKUP फ़ंक्शन में col_num 2 है, इसलिए CHOOSE फ़ंक्शन डिस्प्ले के रूप में CHOOSE(2, B1:B7,A1:A7), का अर्थ है A1:A7 में से मान चुनना।

---

Ex6 - दी गई तारीख के आधार पर कार्यदिवस या महीना लौटाएँ

उसके साथ CHOOSE फ़ंक्शन, आप किसी दी गई तारीख के आधार पर संबंधित कार्यदिवस और महीना भी लौटा सकते हैं।

फ़ॉर्मूला 1: कार्यदिवस को एक तारीख तक वापस करें

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

के बारे में बताएं:

WEEKDAY(): दिए गए दिनांक की कार्यदिवस संख्या प्राप्त करने के लिए Index_num तर्क, उदाहरण के लिए, WEEKDAY(A5) 6 लौटाता है, तो Index_num तर्क 6 होता है।

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": मूल्य सूची तर्क, "रविवार" से शुरू करें क्योंकि कार्यदिवस संख्या "1" "रविवार" को इंगित करती है।

फ़ॉर्मूला 2: तारीख के हिसाब से महीना वापस करें

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

के बारे में बताएं:

MONTH(): Index_num तर्क, जो दी गई तारीख से माह संख्या प्राप्त करता है, उदाहरण के लिए, MONTH(A5) 3 लौटाता है।

---

Ex7 - आज के आधार पर अगले कार्यदिवस/सप्ताहांत तिथि पर लौटें

दैनिक कार्य में, आप आज के आधार पर अगले कार्यदिवस या सप्ताहांत की गणना करना चाह सकते हैं। यहां ही CHOOSE फ़ंक्शन भी आपका उपकार कर सकता है.

उदाहरण के लिए, आज 12/20/2018, गुरुवार है, अब आपको अगला कार्यदिवस और सप्ताहांत प्राप्त करना होगा।

फ़ॉर्मूला 1: आज की तारीख प्राप्त करें

=TODAY()

परिणाम: 12/20/2018

फ़ॉर्मूला 2: आज का कार्यदिवस संख्या प्राप्त करें

=WEEKDAY(TODAY())

परिणाम: 5 (जबकि आज 12/20/2018 है)

नीचे दिखाए गए स्क्रीनशॉट के अनुसार कार्यदिवस संख्या सूची:

फ़ॉर्मूला 3: अगला कार्यदिवस प्राप्त करें

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

के बारे में बताएं:

Today(): वर्तमान दिनांक लौटाएँ

WEEKDAY(TODAY()): index_num तर्क में CHOOSE फ़ंक्शन, आज का कार्यदिवस संख्या प्राप्त करें, उदाहरण के लिए, रविवार 1 है, सोमवार 2 है...

1,1,1,1,1,3,2: में मूल्य सूची तर्क CHOOSE समारोह। उदाहरण के लिए, यदि कार्यदिवस(आज()) 1 (रविवार) लौटाता है, तो यह मानों की सूची से 1 चुनता है, फिर पूरा सूत्र =आज()+1 में बदल जाता है, जिसका अर्थ है कि अगले सोमवार को वापस आने के लिए 1 दिन जोड़ना है। यदि कार्यदिवस (आज ()) 6 (शुक्रवार) लौटाता है, तो यह मानों की सूची से 3 चुनता है, क्योंकि शुक्रवार अगले सोमवार से 3 दिन दूर है।

परिणाम (जबकि आज 12/20/2018 है):

=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)

=12/20/2018+1

=12/21/2018

फ़ॉर्मूला 4: अगले सप्ताहांत का दिन प्राप्त करें

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

के बारे में बताएं:

6,5,4,3,2,1,1: में मूल्य सूची तर्क CHOOSE समारोह। उदाहरण के लिए, यदि कार्यदिवस(आज()) 1 (रविवार) लौटाता है, तो यह मानों की सूची से 6 चुनता है, फिर पूरा सूत्र =आज()+6 में बदल जाता है, जिसका अर्थ है 6 दिन जोड़ना और अगले शनिवार को वापस आना।

रिजल्ट:

=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)

=12/20/2018+2

=12/22/2018

---

नमूना फ़ाइल