एक्सेल ड्रॉप-डाउन सूची में एकाधिक आइटम चुनें - संपूर्ण मार्गदर्शिका
एक्सेल ड्रॉप-डाउन सूचियाँ डेटा स्थिरता और प्रविष्टि में आसानी सुनिश्चित करने के लिए एक शानदार उपकरण हैं। हालाँकि, डिफ़ॉल्ट रूप से, वे आपको केवल एक आइटम का चयन करने तक सीमित रखते हैं। लेकिन क्या होगा यदि आपको एक ही ड्रॉप-डाउन सूची से एकाधिक आइटम चुनने की आवश्यकता हो? यह व्यापक मार्गदर्शिका एक्सेल ड्रॉप-डाउन सूचियों में एकाधिक चयनों को सक्षम करने, डुप्लिकेट प्रबंधित करने, कस्टम विभाजक सेट करने और इन सूचियों के दायरे को परिभाषित करने के तरीकों का पता लगाएगी।
- डुप्लिकेट आइटम की अनुमति देना
- किसी भी मौजूदा आइटम को हटाना
- एक कस्टम विभाजक सेट करना
- एक निर्दिष्ट सीमा निर्धारित करना
- संरक्षित वर्कशीट में निष्पादन
ड्रॉप-डाउन सूची में एकाधिक चयन सक्षम करना
यह अनुभाग एक्सेल में ड्रॉप-डाउन सूची में एकाधिक चयन सक्षम करने में आपकी सहायता के लिए दो विधियाँ प्रदान करता है।
वीबीए कोड का उपयोग करना
ड्रॉप-डाउन सूची में एकाधिक चयन की अनुमति देने के लिए, आप इसका उपयोग कर सकते हैं अनुप्रयोगों के लिए विजुअल बेसिक (वीबीए) एक्सेल में। स्क्रिप्ट ड्रॉप-डाउन सूची के व्यवहार को संशोधित करके इसे बहुविकल्पी सूची बना सकती है। कृपया निम्नानुसार करें.
चरण 1: शीट (कोड) संपादक खोलें
- वह वर्कशीट खोलें जिसमें ड्रॉप-डाउन सूची है जिसके लिए आप एकाधिक चयन सक्षम करना चाहते हैं।
- शीट टैब पर राइट क्लिक करें और चुनें कोड देखें संदर्भ मेनू से
चरण 2: वीबीए कोड का उपयोग करें
अब निम्नलिखित VBA कोड को कॉपी करें और इसे ओपनिंग शीट (कोड) विंडो पर पेस्ट करें।
वीबीए कोड: एक्सेल ड्रॉप-डाउन सूची में एकाधिक चयन सक्षम करें।
Private Sub Worksheet_Change(ByVal Target As Range)
'Updated by Extendoffice 20240118
Dim xRng As Range
Dim xValue1 As String
Dim xValue2 As String
Dim delimiter As String
Dim TargetRange As Range
Set TargetRange = Me.UsedRange ' Users can change target range here
delimiter = ", " ' Users can change the delimiter here
If Target.Count > 1 Or Intersect(Target, TargetRange) Is Nothing Then Exit Sub
On Error Resume Next
Set xRng = TargetRange.SpecialCells(xlCellTypeAllValidation)
If xRng Is Nothing Then Exit Sub
Application.EnableEvents = False
xValue2 = Target.Value
Application.Undo
xValue1 = Target.Value
Target.Value = xValue2
If xValue1 <> "" And xValue2 <> "" Then
If Not (xValue1 = xValue2 Or _
InStr(1, xValue1, delimiter & xValue2) > 0 Or _
InStr(1, xValue1, xValue2 & delimiter) > 0) Then
Target.Value = xValue1 & delimiter & xValue2
Else
Target.Value = xValue1
End If
End If
Application.EnableEvents = True
On Error GoTo 0
End Sub
परिणाम
जब आप वर्कशीट पर लौटेंगे, तो ड्रॉप-डाउन सूची आपको कई विकल्प चुनने में सक्षम करेगी, नीचे डेमो देखें:
उपरोक्त VBA कोड:
- वर्तमान वर्कशीट में मौजूद सभी डेटा सत्यापन ड्रॉप-डाउन सूचियों पर लागू होता है, मौजूदा और भविष्य में बनाई गई दोनों सूचियों पर।
- आपको प्रत्येक ड्रॉप-डाउन सूची में एक ही आइटम को एक से अधिक बार चुनने से रोकता है।
- चयनित आइटम के लिए विभाजक के रूप में अल्पविराम का उपयोग करता है। कृपया अन्य सीमांकक का उपयोग करें विभाजक को बदलने के लिए इस अनुभाग को देखें.
कुछ ही क्लिक में एक्सेल के लिए कुटूल का उपयोग करना
यदि आप वीबीए के साथ सहज नहीं हैं, तो एक आसान विकल्प है एक्सेल के लिए कुटूल's बहु-चयन ड्रॉप-डाउन सूची विशेषता। यह उपयोगकर्ता-अनुकूल उपकरण ड्रॉप-डाउन सूचियों में कई चयनों को सक्षम करने को सरल बनाता है, जिससे आप विभाजक को अनुकूलित कर सकते हैं और अपनी विभिन्न आवश्यकताओं को पूरा करने के लिए आसानी से डुप्लिकेट प्रबंधित कर सकते हैं।
बाद एक्सेल के लिए कुटूल स्थापित करना, के पास जाओ कुटूल टैब, चयन करें ड्राॅप डाउन लिस्ट > बहु-चयन ड्रॉप-डाउन सूची. फिर आपको निम्नानुसार कॉन्फ़िगर करने की आवश्यकता है।
- ड्रॉप-डाउन सूची वाली वह श्रेणी निर्दिष्ट करें जिसमें से आपको एकाधिक आइटम चुनने की आवश्यकता है।
- ड्रॉप-डाउन सूची सेल में चयनित आइटम के लिए विभाजक निर्दिष्ट करें।
- क्लिक करें OK सेटिंग्स को पूरा करने के लिए।
परिणाम
अब, जब आप निर्दिष्ट सीमा में ड्रॉप-डाउन सूची वाले सेल पर क्लिक करते हैं, तो उसके बगल में एक सूची बॉक्स दिखाई देगा। आइटमों को ड्रॉप-डाउन सेल में जोड़ने के लिए बस उनके बगल में "+" बटन पर क्लिक करें, और जो आइटम आप अब नहीं चाहते हैं उन्हें हटाने के लिए "-" बटन पर क्लिक करें। नीचे डेमो देखें:
- चेक सेपरेटर डालने के बाद टेक्स्ट को लपेटें विकल्प यदि आप चयनित आइटम को सेल के भीतर लंबवत रूप से प्रदर्शित करना चाहते हैं। यदि आप क्षैतिज सूची पसंद करते हैं, तो इस विकल्प को अनियंत्रित छोड़ दें।
- चेक खोज सक्षम करें विकल्प यदि आप अपनी ड्रॉप-डाउन सूची में एक खोज बार जोड़ना चाहते हैं।
- कृपया इस सुविधा को लागू करने के लिए एक्सेल के लिए कुटूल डाउनलोड और इंस्टॉल करें पहले।
बहु-चयन ड्रॉप-डाउन सूची के लिए अधिक संचालन
यह अनुभाग उन विभिन्न परिदृश्यों को एकत्रित करता है जिनकी आवश्यकता डेटा सत्यापन ड्रॉप-डाउन सूची में एकाधिक चयनों को सक्षम करते समय हो सकती है।
ड्रॉप-डाउन सूची में डुप्लिकेट आइटम की अनुमति देना
जब ड्रॉप-डाउन सूची में एकाधिक चयन की अनुमति दी जाती है तो डुप्लिकेट एक समस्या हो सकती है। उपरोक्त VBA कोड ड्रॉप-डाउन सूची में डुप्लिकेट आइटम की अनुमति नहीं देता है। यदि आपको डुप्लिकेट आइटम रखने की आवश्यकता है, तो इस अनुभाग में VBA कोड आज़माएँ।
वीबीए कोड: डेटा सत्यापन ड्रॉप-डाउन सूची में डुप्लिकेट की अनुमति दें
Private Sub Worksheet_Change(ByVal Target As Range)
'Updated by Extendoffice 20240118
Dim xRng As Range
Dim xValue1 As String
Dim xValue2 As String
Dim delimiter As String
Dim TargetRange As Range
Set TargetRange = Me.UsedRange ' Users can change target range here
delimiter = ", " ' Users can change the delimiter here
If Target.Count > 1 Or Intersect(Target, TargetRange) Is Nothing Then Exit Sub
On Error Resume Next
Set xRng = TargetRange.SpecialCells(xlCellTypeAllValidation)
If xRng Is Nothing Then Exit Sub
Application.EnableEvents = False
xValue2 = Target.Value
Application.Undo
xValue1 = Target.Value
Target.Value = xValue2
If xValue1 <> "" And xValue2 <> "" Then
Target.Value = xValue1 & delimiter & xValue2
End If
Application.EnableEvents = True
On Error GoTo 0
End Sub
परिणाम
अब आप वर्तमान वर्कशीट में ड्रॉप-डाउन सूचियों से एकाधिक आइटम का चयन कर सकते हैं। ड्रॉप-डाउन सूची सेल में किसी आइटम को दोहराने के लिए, सूची से उस आइटम का चयन करना जारी रखें। स्क्रीनशॉट देखें:
ड्रॉप-डाउन सूची से किसी भी मौजूदा आइटम को हटाना
ड्रॉप-डाउन सूची से एकाधिक आइटम चुनने के बाद, आपको कभी-कभी ड्रॉप-डाउन सूची सेल से किसी मौजूदा आइटम को हटाने की आवश्यकता हो सकती है। यह अनुभाग इस कार्य को पूरा करने में आपकी सहायता के लिए VBA कोड का एक और भाग प्रदान करता है।
वीबीए कोड: ड्रॉप-डाउन सूची सेल से किसी भी मौजूदा आइटम को हटा दें
Private Sub Worksheet_Change(ByVal Target As Range)
'Updated by Extendoffice 20240118
Dim xRngDV As Range
Dim TargetRange As Range
Dim oldValue As String
Dim newValue As String
Dim delimiter As String
Dim allValues As Variant
Dim valueExists As Boolean
Dim i As Long
Dim cleanedValue As String
Set TargetRange = Me.UsedRange ' Set your specific range here
delimiter = ", " ' Set your desired delimiter here
If Target.CountLarge > 1 Then Exit Sub
' Check if the change is within the specific range
If Intersect(Target, TargetRange) Is Nothing Then Exit Sub
On Error Resume Next
Set xRngDV = Target.SpecialCells(xlCellTypeAllValidation)
If xRngDV Is Nothing Or Target.Value = "" Then
' Skip if there's no data validation or if the cell is cleared
Application.EnableEvents = True
Exit Sub
End If
On Error GoTo 0
If Not Intersect(Target, xRngDV) Is Nothing Then
Application.EnableEvents = False
newValue = Target.Value
Application.Undo
oldValue = Target.Value
Target.Value = newValue
' Split the old value by delimiter and check if new value already exists
allValues = Split(oldValue, delimiter)
valueExists = False
For i = LBound(allValues) To UBound(allValues)
If Trim(allValues(i)) = newValue Then
valueExists = True
Exit For
End If
Next i
' Add or remove value based on its existence
If valueExists Then
' Remove the value
cleanedValue = ""
For i = LBound(allValues) To UBound(allValues)
If Trim(allValues(i)) <> newValue Then
If cleanedValue <> "" Then cleanedValue = cleanedValue & delimiter
cleanedValue = cleanedValue & Trim(allValues(i))
End If
Next i
Target.Value = cleanedValue
Else
' Add the value
If oldValue <> "" Then
Target.Value = oldValue & delimiter & newValue
Else
Target.Value = newValue
End If
End If
Application.EnableEvents = True
End If
End Sub
परिणाम
यह वीबीए कोड आपको ड्रॉप-डाउन सूची से कई आइटम चुनने और आपके द्वारा पहले से चुने गए किसी भी आइटम को आसानी से हटाने की अनुमति देता है। एकाधिक आइटम चुनने के बाद, यदि आप किसी विशिष्ट आइटम को हटाना चाहते हैं, तो बस उसे सूची से फिर से चुनें।
एक कस्टम विभाजक सेट करना
उपरोक्त VBA कोड में सीमांकक को अल्पविराम के रूप में सेट किया गया है। आप ड्रॉप-डाउन सूची चयनों के लिए विभाजक के रूप में उपयोग करने के लिए इस चर को किसी भी पसंदीदा वर्ण में संशोधित कर सकते हैं। यहां बताया गया है कि आप यह कैसे कर सकते हैं:
जैसा कि आप देख सकते हैं कि उपरोक्त सभी VBA कोड में निम्नलिखित पंक्ति है:
delimiter = ", "
आपको बस आवश्यकतानुसार अल्पविराम को किसी भी विभाजक में बदलना होगा। उदाहरण के लिए, आप आइटमों को अर्धविराम से अलग करना चाहते हैं, पंक्ति को इसमें बदलें:
delimiter = "; "
delimiter = vbNewLine
एक निर्दिष्ट सीमा निर्धारित करना
उपरोक्त VBA कोड वर्तमान वर्कशीट में सभी ड्रॉप-डाउन सूचियों पर लागू होते हैं। यदि आप चाहते हैं कि वीबीए कोड केवल ड्रॉप-डाउन सूचियों की एक निश्चित सीमा पर लागू हों, तो आप उपरोक्त वीबीए कोड में निम्नानुसार सीमा निर्दिष्ट कर सकते हैं।
जैसा कि आप देख सकते हैं कि उपरोक्त सभी VBA कोड में निम्नलिखित पंक्ति है:
Set TargetRange = Me.UsedRange
आपको बस इस पंक्ति को बदलने की आवश्यकता है:
Set TargetRange = Me.Range("C2:C10")
संरक्षित वर्कशीट में निष्पादन
कल्पना करें कि आपने किसी वर्कशीट को पासवर्ड से सुरक्षित कर लिया है"123" और ड्रॉप-डाउन सूची कक्षों को " पर सेट करेंखुला"सुरक्षा को सक्रिय करने से पहले, इस प्रकार यह सुनिश्चित करना कि सुरक्षा के बाद बहु-चयन फ़ंक्शन सक्रिय रहता है। हालाँकि, ऊपर उल्लिखित VBA कोड इस मामले में काम नहीं कर सकते हैं, और यह अनुभाग एक अन्य VBA स्क्रिप्ट का वर्णन करता है जो विशेष रूप से बहु-चयन कार्यक्षमता को संभालने के लिए डिज़ाइन किया गया है एक संरक्षित कार्यपत्रक में.
वीबीए कोड: डुप्लिकेट के बिना ड्रॉप-डाउन सूची में एकाधिक चयन सक्षम करें
Private Sub Worksheet_Change(ByVal Target As Range)
'Updated by Extendoffice 20240118
Dim xRng As Range
Dim xValue1 As String
Dim xValue2 As String
Dim delimiter As String
Dim TargetRange As Range
Dim isProtected As Boolean
Dim pswd As Variant
Set TargetRange = Me.UsedRange ' Set your specific range here
delimiter = ", " ' Users can change the delimiter here
If Target.Count > 1 Or Intersect(Target, TargetRange) Is Nothing Then Exit Sub
' Check if sheet is protected
isProtected = Me.ProtectContents
If isProtected Then
' If protected, temporarily unprotect. Adjust or remove the password as needed.
pswd = "yourPassword" ' Change or remove this as needed
Me.Unprotect Password:=pswd
End If
On Error Resume Next
Set xRng = TargetRange.SpecialCells(xlCellTypeAllValidation)
If xRng Is Nothing Then
If isProtected Then Me.Protect Password:=pswd
Exit Sub
End If
Application.EnableEvents = False
xValue2 = Target.Value
Application.Undo
xValue1 = Target.Value
Target.Value = xValue2
If xValue1 <> "" And xValue2 <> "" Then
If Not (xValue1 = xValue2 Or _
InStr(1, xValue1, delimiter & xValue2) > 0 Or _
InStr(1, xValue1, xValue2 & delimiter) > 0) Then
Target.Value = xValue1 & delimiter & xValue2
Else
Target.Value = xValue1
End If
End If
Application.EnableEvents = True
On Error GoTo 0
' Re-protect the sheet if it was protected
If isProtected Then
Me.Protect Password:=pswd
End If
End Sub
एक्सेल ड्रॉप-डाउन सूचियों में एकाधिक चयन सक्षम करके, आप अपनी वर्कशीट की कार्यक्षमता और लचीलेपन को काफी बढ़ा सकते हैं। चाहे आप वीबीए कोडिंग के साथ सहज हों या कुटूल जैसे अधिक सरल समाधान पसंद करते हों, अब आपके पास अपनी मानक ड्रॉप-डाउन सूचियों को गतिशील, बहु-चयन टूल में बदलने की क्षमता है। इन कौशलों के साथ, अब आप अधिक गतिशील और उपयोगकर्ता-अनुकूल एक्सेल दस्तावेज़ बनाने में सक्षम हैं। एक्सेल की क्षमताओं को गहराई से जानने के इच्छुक लोगों के लिए, हमारी वेबसाइट में ढेर सारे ट्यूटोरियल हैं। यहां अधिक एक्सेल टिप्स और ट्रिक्स खोजें.
संबंधित आलेख
एक्सेल ड्रॉप डाउन सूची में टाइप करते समय स्वतः पूर्ण
यदि आपके पास बड़े मानों के साथ डेटा सत्यापन ड्रॉप डाउन सूची है, तो आपको उचित सूची खोजने के लिए सूची में नीचे स्क्रॉल करना होगा, या पूरे शब्द को सीधे सूची बॉक्स में टाइप करना होगा। यदि ड्रॉप डाउन सूची में पहला अक्षर टाइप करते समय स्वतः पूर्ण होने की अनुमति देने की कोई विधि है, तो सब कुछ आसान हो जाएगा। यह ट्यूटोरियल समस्या को हल करने की विधि प्रदान करता है।
एक्सेल में किसी अन्य कार्यपुस्तिका से ड्रॉप डाउन सूची बनाएं
किसी कार्यपुस्तिका के भीतर कार्यपत्रकों के बीच डेटा सत्यापन ड्रॉप डाउन सूची बनाना काफी आसान है। लेकिन यदि डेटा सत्यापन के लिए आपको आवश्यक सूची डेटा किसी अन्य कार्यपुस्तिका में मिल जाए, तो आप क्या करेंगे? इस ट्यूटोरियल में, आप विस्तार से सीखेंगे कि एक्सेल में किसी अन्य कार्यपुस्तिका से ड्रॉपडाउन सूची कैसे बनाई जाती है।
एक्सेल में खोजने योग्य ड्रॉप डाउन सूची बनाएं
अनेक मानों वाली ड्रॉप डाउन सूची के लिए, उचित मान ढूँढना कोई आसान काम नहीं है। पहले हमने ड्रॉप डाउन बॉक्स में पहला अक्षर दर्ज करने पर ड्रॉप डाउन सूची को स्वत: पूरा करने की एक विधि पेश की थी। स्वत: पूर्ण फ़ंक्शन के अलावा, आप ड्रॉप डाउन सूची में उचित मान खोजने में कार्य कुशलता बढ़ाने के लिए ड्रॉप डाउन सूची को खोजने योग्य भी बना सकते हैं। ड्रॉप डाउन सूची को खोजने योग्य बनाने के लिए, इस ट्यूटोरियल में दी गई विधि को आज़माएँ।
एक्सेल ड्रॉप डाउन सूची में मानों का चयन करते समय अन्य सेल स्वतः भर जाते हैं
मान लीजिए कि आपने सेल रेंज B8:B14 के मानों के आधार पर एक ड्रॉप डाउन सूची बनाई है। जब आप ड्रॉप डाउन सूची में कोई मान चुनते हैं, तो आप चाहते हैं कि सेल श्रेणी C8:C14 में संबंधित मान चयनित सेल में स्वचालित रूप से पॉप्युलेट हो जाएं। समस्या को हल करने के लिए, इस ट्यूटोरियल में दी गई विधियाँ आपकी मदद करेंगी।
सर्वोत्तम कार्यालय उत्पादकता उपकरण
एक्सेल के लिए कुटूल के साथ अपने एक्सेल कौशल को सुपरचार्ज करें, और पहले जैसी दक्षता का अनुभव करें। एक्सेल के लिए कुटूल उत्पादकता बढ़ाने और समय बचाने के लिए 300 से अधिक उन्नत सुविधाएँ प्रदान करता है। वह सुविधा प्राप्त करने के लिए यहां क्लिक करें जिसकी आपको सबसे अधिक आवश्यकता है...
ऑफिस टैब ऑफिस में टैब्ड इंटरफ़ेस लाता है, और आपके काम को बहुत आसान बनाता है
- Word, Excel, PowerPoint में टैब्ड संपादन और रीडिंग सक्षम करें, प्रकाशक, एक्सेस, विसियो और प्रोजेक्ट।
- नई विंडो के बजाय एक ही विंडो के नए टैब में एकाधिक दस्तावेज़ खोलें और बनाएं।
- आपकी उत्पादकता 50% बढ़ जाती है, और आपके लिए हर दिन सैकड़ों माउस क्लिक कम हो जाते हैं!
विषय - सूची
- एकाधिक चयन सक्षम करना
- वीबीए कोड का उपयोग करना
- कुछ ही क्लिक में एक्सेल के लिए कुटूल का उपयोग करना
- अधिक संचालन
- डुप्लिकेट आइटम की अनुमति देना
- किसी भी मौजूदा आइटम को हटाना
- एक कस्टम विभाजक सेट करना
- एक निर्दिष्ट सीमा निर्धारित करना
- संरक्षित वर्कशीट में निष्पादन
- संबंधित आलेख
- सर्वोत्तम कार्यालय उत्पादकता उपकरण
- टिप्पणियाँ