एक्सेल से आउटलुक के माध्यम से सेल की रेंज कैसे भेजें/ईमेल करें?
क्या आपको कभी ऐसी समस्या का सामना करना पड़ा है कि किसी कार्यपत्रक में एक रिपोर्ट समाप्त करने के बाद, और आपको इस कार्यपत्रक में कई कक्षों में भेजने की आवश्यकता होती है जिसमें आपके विशिष्ट प्राप्तकर्ता के लिए कुछ महत्वपूर्ण डेटा होते हैं। क्या आपके लिए आउटलुक खोले बिना एक्सेल से इस रेंज को ईमेल करने का कोई त्वरित तरीका है?
VBA कोड के साथ Excel से अनुलग्नक के रूप में कक्षों की श्रेणी भेजें
वीबीए कोड के साथ एक्सेल से बॉडी के रूप में सेल की रेंज भेजें
VBA कोड के साथ Excel से अनुलग्नक के रूप में कक्षों की श्रेणी भेजें
निम्नलिखित वीबीए कोड आपकी चयनित रेंज को एक्सेल में अटैचमेंट के रूप में भेजने में आपकी मदद कर सकता है। कृपया इस प्रकार करें:
1. अपनी कार्यपुस्तिका खोलें और फिर दबाए रखें ALT + F11 कुंजी को खोलने के लिए एप्लीकेशन विंडो के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक.
2। क्लिक करें सम्मिलित करें > मॉड्यूल, और निम्नलिखित कोड को इसमें पेस्ट करें मॉड्यूल विंडो.
VBA कोड: Excel से अनुलग्नक के रूप में कक्षों की श्रेणी भेजें
Sub SendRange()
'Update 20131209
Dim xFile As String
Dim xFormat As Long
Dim Wb As Workbook
Dim Wb2 As Workbook
Dim Ws As Worksheet
Dim FilePath As String
Dim FileName As String
Dim OutlookApp As Object
Dim OutlookMail As Object
Dim WorkRng As Range
xTitleId = "KutoolsforExcel"
Set WorkRng = Application.Selection
Set WorkRng = Application.InputBox("Range", xTitleId, WorkRng.Address, Type:=8)
Application.ScreenUpdating = False
Application.DisplayAlerts = False
Set Wb = Application.ActiveWorkbook
Wb.Worksheets.Add
Set Ws = Application.ActiveSheet
WorkRng.Copy Ws.Cells(1, 1)
Ws.Copy
Set Wb2 = Application.ActiveWorkbook
Select Case Wb.FileFormat
Case xlOpenXMLWorkbook:
xFile = ".xlsx"
xFormat = xlOpenXMLWorkbook
Case xlOpenXMLWorkbookMacroEnabled:
If Wb2.HasVBProject Then
xFile = ".xlsm"
xFormat = xlOpenXMLWorkbookMacroEnabled
Else
xFile = ".xlsx"
xFormat = xlOpenXMLWorkbook
End If
Case Excel8:
xFile = ".xls"
xFormat = Excel8
Case xlExcel12:
xFile = ".xlsb"
xFormat = xlExcel12
End Select
FilePath = Environ$("temp") & "\"
FileName = Wb.Name & Format(Now, "dd-mmm-yy h-mm-ss")
Set OutlookApp = CreateObject("Outlook.Application")
Set OutlookMail = OutlookApp.CreateItem(0)
Wb2.SaveAs FilePath & FileName & xFile, FileFormat:=xFormat
With OutlookMail
.To = ""
.CC = ""
.BCC = ""
.Subject = "information of kte"
.Body = "hello, please check and read this document. "
.Attachments.Add Wb2.FullName
.Send
End With
Wb2.Close
Kill FilePath & FileName & xFile
Set OutlookMail = Nothing
Set OutlookApp = Nothing
Ws.Delete
Application.DisplayAlerts = True
Application.ScreenUpdating = True
End Sub
नोट: उपरोक्त कोड में, आप निम्नलिखित जानकारी को अपनी आवश्यकता के अनुसार बदल सकते हैं।
- .को = ""
- .सीसी = ""
- .बीसीसी = ""
- .विषय = "केटीई की जानकारी"
- .बॉडी = "हैलो, कृपया इस दस्तावेज़ को जांचें और पढ़ें।"
3। तब दबायें F5 इस कोड को चलाने के लिए कुंजी, और एक प्रॉम्प्ट बॉक्स आपको उस श्रेणी का चयन करने की याद दिलाने के लिए पॉप अप होगा जिसे आप भेजना चाहते हैं। स्क्रीनशॉट देखें:
4। तब दबायें OK, और एक प्रॉम्प्ट बॉक्स दिखाई देगा, प्रगति पट्टी समाप्त होने के बाद, क्लिक करें अनुमति देना, और फिर कोशिकाओं की विशिष्ट श्रेणी आपके प्राप्तकर्ता को अनुलग्नक के रूप में भेज दी गई है।
वीबीए कोड के साथ एक्सेल से बॉडी के रूप में सेल की रेंज भेजें
यदि आप Excel से संदेश के मुख्य भाग के रूप में एक विशिष्ट श्रेणी भेजना चाहते हैं, तो आप इसे हल करने के लिए निम्नलिखित VBA कोड भी लागू कर सकते हैं।
एक्सेल के लिए कुटूल, से अधिक के साथ 120 सुविधाजनक कार्य, आपके काम को आसान बनाते हैं। | ||
1. अपनी वर्कशीट सक्रिय करें और दबाए रखें ALT + F11 कुंजी को खोलने के लिए एप्लीकेशन विंडो के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक.
2। क्लिक करें सम्मिलित करें > मॉड्यूल, और निम्नलिखित कोड को इसमें पेस्ट करें मॉड्यूल विंडो.
वीबीए कोड: एक्सेल से बॉडी के रूप में सेल की रेंज भेजें
Sub EmailRange()
'Update 20131209
Dim WorkRng As Range
On Error Resume Next
xTitleId = "KutoolsforExcel"
Set WorkRng = Application.Selection
Set WorkRng = Application.InputBox("Range", xTitleId, WorkRng.Address, Type:=8)
Application.ScreenUpdating = False
WorkRng.Select
ActiveWorkbook.EnvelopeVisible = True
With ActiveSheet.MailEnvelope
.Introduction = "Please read this email."
.Item.To = ""
.Item.Subject = "information of kte"
.Item.Send
End With
Application.ScreenUpdating = True
End Sub
नोट: उपरोक्त कोड में, आप निम्नलिखित जानकारी को अपनी आवश्यकता के अनुसार बदल सकते हैं।
- .परिचय = "कृपया यह ईमेल पढ़ें।"
- .आइटम.टू = ""
- .आइटम.विषय = "केटीई की जानकारी"
3। तब दबायें F5 इस कोड को चलाने के लिए कुंजी, और एक प्रॉम्प्ट बॉक्स आपको उस श्रेणी का चयन करने की याद दिलाने के लिए पॉप अप होगा जिसे आप भेजना चाहते हैं।
4. तब क्लिक करो OK, और एक प्रॉम्प्ट बॉक्स दिखाई देगा, प्रगति पट्टी समाप्त होने के बाद, क्लिक करें अनुमति देना, और फिर कोशिकाओं की विशिष्ट श्रेणी आपके प्राप्तकर्ता को संदेश के मुख्य भाग के रूप में भेज दी गई है।
टिप्पणियाँ:
1. ये कोड केवल तभी उपलब्ध होते हैं जब आउटलुक आपके मेल प्रोग्राम के रूप में हो।
2. वर्तमान वर्कशीट भेजने के बाद, आप अपने आउटलुक पर जाकर यह सुनिश्चित कर सकते हैं कि ईमेल सफलतापूर्वक भेजा गया है या नहीं।
संबंधित आलेख:
एक्सेल से केवल आउटलुक के माध्यम से वर्कशीट कैसे भेजें?
एक्सेल से आउटलुक के माध्यम से वर्तमान कार्यपुस्तिका कैसे भेजें?
सर्वोत्तम कार्यालय उत्पादकता उपकरण
एक्सेल के लिए कुटूल के साथ अपने एक्सेल कौशल को सुपरचार्ज करें, और पहले जैसी दक्षता का अनुभव करें। एक्सेल के लिए कुटूल उत्पादकता बढ़ाने और समय बचाने के लिए 300 से अधिक उन्नत सुविधाएँ प्रदान करता है। वह सुविधा प्राप्त करने के लिए यहां क्लिक करें जिसकी आपको सबसे अधिक आवश्यकता है...
ऑफिस टैब ऑफिस में टैब्ड इंटरफ़ेस लाता है, और आपके काम को बहुत आसान बनाता है
- Word, Excel, PowerPoint में टैब्ड संपादन और रीडिंग सक्षम करें, प्रकाशक, एक्सेस, विसियो और प्रोजेक्ट।
- नई विंडो के बजाय एक ही विंडो के नए टैब में एकाधिक दस्तावेज़ खोलें और बनाएं।
- आपकी उत्पादकता 50% बढ़ जाती है, और आपके लिए हर दिन सैकड़ों माउस क्लिक कम हो जाते हैं!