आउटलुक: यदि कोई प्रतिक्रिया न हो तो ईमेल को स्वतः पुनः कैसे भेजें

जब आप अपने सहकर्मी या सहयोगी भागीदार या किसी को ईमेल भेजते हैं और तत्काल प्रतिक्रिया की आवश्यकता होती है, तो यदि प्रतिक्रिया निर्दिष्ट समय से पहले नहीं आती है तो आप एक ऑटो पुनः भेजें ईमेल सेटिंग सेट कर सकते हैं।

यदि कोई प्रतिक्रिया न हो तो स्वत: पुनः भेजें सेट करने के लिए रिमाइंडर और वीबीए का उपयोग करना

यदि कोई प्रतिक्रिया न हो तो स्वत: पुनः भेजें सेट करने के लिए रिमाइंडर और वीबीए का उपयोग करना

भाग 1: एक निर्दिष्ट समय में याद दिलाने के लिए अनुस्मारक सेट करें

1. किसी ईमेल (भेजे गए आइटम फ़ोल्डर से) पर राइट क्लिक करें जिसे आप कोई प्रतिक्रिया नहीं होने पर दोबारा भेजना चाहते हैं, पॉपिंग संदर्भ मेनू में, क्लिक करें ऊपर का पालन करें > रिमाइंडर जोड़ें.

2. पॉपिंग में रिवाज संवाद, रखें अनुस्मारक चेकबॉक्स पर टिक करें, फिर नीचे ड्रॉप-डाउन बॉक्स में, वह दिनांक और समय चुनें जिससे आप चाहते हैं कि प्रतिक्रिया पहले आ जाए, साथ ही आप सीधे बॉक्स में दिनांक और समय भी टाइप कर सकते हैं। क्लिक OK.

भाग 2: यदि निर्दिष्ट समय में कोई प्रतिक्रिया नहीं मिलती है तो ईमेल दोबारा भेजने के लिए वीबीए डालें

3। दबाएँ ऑल्ट + F11 सक्षम करने के लिए कुंजियाँ अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

4। डबल क्लिक करें यह आउटलुक सत्र में प्रोजेक्ट - प्रोजेक्ट1 एक रिक्त स्क्रिप्ट बनाने के लिए फलक, और नीचे दिए गए VBA कोड को कॉपी करके रिक्त स्क्रिप्ट में पेस्ट करें।

वीबीए: यदि कोई प्रतिक्रिया न हो तो ईमेल दोबारा भेजें

Public WithEvents GInboxItems As Outlook.Items
'UpdatebyExtendoffice20220413
Private Sub Application_Startup()
  Dim xInboxFld As Folder
  Set xInboxFld = Application.Session.GetDefaultFolder(olFolderInbox)
  Set GInboxItems = xInboxFld.Items
End Sub

'Judge
Private Sub GInboxItems_ItemAdd(ByVal Item As Object)
  Dim xSentItems As Outlook.Items
  Dim xMail As MailItem
  Dim i As Long
  Dim xSubject As String
  Dim xItemSubject As String
  Dim xSendTime As String
  On Error Resume Next
  Set xSentItems = Application.Session.GetDefaultFolder(olFolderSentMail).Items
  If Item.Class <> olMail Then Exit Sub
  For i = xSentItems.Count To 1 Step -1
    If xSentItems.Item(i).Class = olMail Then
      Set xMail = xSentItems.Item(i)
      xSubject = LCase(xMail.Subject)
      xSendTime = xMail.SentOn
      xItemSubject = LCase(Item.Subject)
      If (xItemSubject = "re: " & xSubject) Or (InStr(xItemSubject, xSubject) > 0) Then
        If Item.SentOn > xSendTime Then
           With xMail
             .ClearTaskFlag
             .ReminderSet = False
             .Save
           End With
        End If
      End If
    End If
  Next i
End Sub

'Reminder
Private Sub Application_Reminder(ByVal Item As Object)
  Dim xPrompt As String
  Dim xResponse As Integer
  Dim xFollowUpMail As Outlook.MailItem
  Dim xRcp As Recipient
  On Error Resume Next
  'Resend
  If (Item.Class <> olMail) Then Exit Sub
  xPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
  xResponse = MsgBox(xPrompt, vbYesNo + vbQuestion, "Kutools for Outlook")
  If xResponse = vbNo Then Exit Sub
  Set xFollowUpMail = Application.CreateItem(olMailItem)
  With xFollowUpMail
    For Each xRcp In Item.Recipients
      .Recipients.Add (xRcp.Address)
    Next
    .Recipients.ResolveAll
    .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
    .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
    .Attachments.Add Item
    .Display
  End With
End Sub

5. कोड सहेजें, फिर मुख्य इंटरफ़ेस पर वापस जाएं, क्लिक करें पट्टिका > ऑप्शंस और वें मेंई आउटलुक विकल्प खिड़की, क्लिक करें विश्वास केंद्र बाएँ फलक में, और क्लिक करें विश्वास केंद्र सेटिंग्स को सक्षम करने के लिए विश्वास केंद्र खिड़की। क्लिक मैक्रो सेटिंग्स और सुनिश्चित करें कि सभी मैक्रोज़ सक्षम करें (अनुशंसित नहीं; संभावित रूप से खतरनाक कोड चल सकता है) विकल्प सही अनुभाग में चुना गया है। क्लिक OK > OK.

6. अब यदि भेजे गए ईमेल, जिसे एक अनुस्मारक के साथ सेट किया गया है, को निर्दिष्ट समय आने पर कोई प्रतिक्रिया नहीं मिलती है, तो एक पॉपिंग डायलॉग आपको यह याद दिलाने के लिए पॉप आउट होता है कि अधिसूचना बनाने के लिए ईमेल को दोबारा भेजना है या नहीं।

7। क्लिक करें हाँ, एक संदेश विंडो बाहर आती है और पिछले ईमेल को संलग्न करती है, और आप मुख्य भाग को फिर से संपादित कर सकते हैं और क्लिक कर सकते हैं भेजें ईमेल पुनः भेजने के लिए..

8। क्लिक करें नहीं, अनुस्मारक हटा दिया जाएगा.

नोट: यदि ईमेल का उत्तर निर्दिष्ट समय से पहले दिया गया है, तो अनुस्मारक VBA द्वारा हटा दिया जाएगा।

---

सर्वोत्तम कार्यालय उत्पादकता उपकरण

आउटलुक के लिए कुटूल - आपके आउटलुक को सुपरचार्ज करने के लिए 100 से अधिक शक्तिशाली सुविधाएँ

🤖 एआई मेल सहायक: एआई जादू के साथ त्वरित प्रो ईमेल - प्रतिभाशाली उत्तरों के लिए एक-क्लिक, सही टोन, बहुभाषी महारत। ईमेलिंग को सहजता से रूपांतरित करें! ...

📧 ईमेल स्वचालन: कार्यालय से बाहर (POP और IMAP के लिए उपलब्ध)  /  ईमेल भेजने का शेड्यूल करें  /  ईमेल भेजते समय नियमों के अनुसार ऑटो सीसी/बीसीसी  /  स्वतः अग्रेषित (उन्नत नियम)   /  स्वतः ग्रीटिंग जोड़ें   /  बहु-प्राप्तकर्ता ईमेल को स्वचालित रूप से अलग-अलग संदेशों में विभाजित करें ...

📨 ईमेल प्रबंधन: आसानी से ईमेल याद रखें  /  विषयों और अन्य लोगों द्वारा घोटाले वाले ईमेल को ब्लॉक करें  /  डुप्लिकेट ईमेल हटाएँ  /  उन्नत खोज  /  फ़ोल्डरों को समेकित करें ...

📁 अनुलग्नक प्रो: बैच सहेजें  /  बैच अलग करना  /  बैच संपीड़न  /  ऑटो सहेजें   /  ऑटो डिटैच  /  ऑटो कंप्रेस ...

🌟 इंटरफ़ेस जादू: 😊अधिक सुंदर और शानदार इमोजी   /  टैब्ड व्यू के साथ अपनी आउटलुक उत्पादकता बढ़ाएँ  /  आउटलुक को बंद करने के बजाय छोटा करें ...

???? एक-क्लिक चमत्कार: आने वाले अनुलग्नकों के साथ सभी को उत्तर दें  /   फ़िशिंग-रोधी ईमेल  /  🕘प्रेषक का समय क्षेत्र दिखाएं ...

👩🏼‍🤝‍👩🏻 संपर्क एवं कैलेंडर: बैच चयनित ईमेल से संपर्क जोड़ें  /  किसी संपर्क समूह को अलग-अलग समूहों में विभाजित करें  /  जन्मदिन अनुस्मारक हटाएँ ...

के ऊपर 100 सुविधाएँ आपके अन्वेषण की प्रतीक्षा करें! अधिक जानने के लिए यहां क्लिक करें।

विस्तार में पढ़ें       मुफ्त डाउनलोड      खरीद फरोख्त