मुख्य सामग्री पर जाएं

एक्सेल में ऋण परिशोधन कार्यक्रम बनाएं - चरण दर चरण ट्यूटोरियल

लेखक: ज़ियाओयांग अंतिम संशोधित: 2024-03-22

एक्सेल में ऋण परिशोधन कार्यक्रम बनाना एक मूल्यवान कौशल हो सकता है, जो आपको अपने ऋण भुगतान को प्रभावी ढंग से देखने और प्रबंधित करने की अनुमति देता है। परिशोधन अनुसूची एक तालिका है जो परिशोधन ऋण (आमतौर पर बंधक या कार ऋण) पर प्रत्येक आवधिक भुगतान का विवरण देती है। यह प्रत्येक भुगतान को ब्याज और मूलधन घटकों में विभाजित करता है, प्रत्येक भुगतान के बाद शेष शेष दिखाता है। आइए एक्सेल में ऐसा शेड्यूल बनाने के लिए चरण-दर-चरण मार्गदर्शिका देखें।

एक परिशोधन अनुसूची क्या है?

Excel में एक परिशोधन शेड्यूल बनाएं

विभिन्न अवधियों के लिए एक परिशोधन कार्यक्रम बनाएं

अतिरिक्त भुगतानों के साथ एक परिशोधन कार्यक्रम बनाएं

एक्सेल टेम्पलेट का उपयोग करके एक परिशोधन कार्यक्रम (अतिरिक्त भुगतान के साथ) बनाएं

नमूना फ़ाइल डाउनलोड करें

एक्सेल में परिशोधन अनुसूची बनाएं

एक परिशोधन अनुसूची क्या है?

परिशोधन अनुसूची ऋण गणना में उपयोग की जाने वाली एक विस्तृत तालिका है जो समय के साथ ऋण चुकाने की प्रक्रिया को प्रदर्शित करती है। परिशोधन अनुसूचियां आमतौर पर बंधक, कार ऋण और व्यक्तिगत ऋण जैसे निश्चित दर वाले ऋणों के लिए उपयोग की जाती हैं, जहां भुगतान राशि पूरे ऋण अवधि के दौरान स्थिर रहती है, लेकिन समय के साथ ब्याज बनाम मूलधन के भुगतान का अनुपात बदल जाता है।

एक्सेल में ऋण परिशोधन कार्यक्रम बनाने के लिए, वास्तव में, अंतर्निहित फ़ंक्शन पीएमटी, पीपीएमटी और आईपीएमटी महत्वपूर्ण हैं। आइए समझें कि प्रत्येक फ़ंक्शन क्या करता है:

  • पीएमटी समारोह: इस फ़ंक्शन का उपयोग निरंतर भुगतान और स्थिर ब्याज दर के आधार पर ऋण के लिए प्रति अवधि कुल भुगतान की गणना करने के लिए किया जाता है।
  • आईपीएमटी फ़ंक्शन: यह फ़ंक्शन किसी निश्चित अवधि के लिए भुगतान के ब्याज हिस्से की गणना करता है।
  • पीपीएमटी फ़ंक्शन: इस फ़ंक्शन का उपयोग किसी विशिष्ट अवधि के लिए भुगतान के मूल भाग की गणना करने के लिए किया जाता है।

एक्सेल में इन कार्यों का उपयोग करके, आप एक विस्तृत परिशोधन कार्यक्रम बना सकते हैं जो प्रत्येक भुगतान के ब्याज और मूल घटकों के साथ-साथ प्रत्येक भुगतान के बाद ऋण की शेष राशि को दर्शाता है।

Excel में एक परिशोधन शेड्यूल बनाएं

इस अनुभाग में, हम Excel में परिशोधन शेड्यूल बनाने के लिए दो अलग-अलग तरीकों का परिचय देंगे। ये विधियां विभिन्न उपयोगकर्ता प्राथमिकताओं और कौशल स्तरों को पूरा करती हैं, जिससे यह सुनिश्चित होता है कि कोई भी, एक्सेल के साथ उनकी दक्षता की परवाह किए बिना, अपने ऋण के लिए एक विस्तृत और सटीक परिशोधन कार्यक्रम सफलतापूर्वक बना सकता है।

सूत्र अंतर्निहित गणनाओं की गहरी समझ प्रदान करते हैं और विशिष्ट आवश्यकताओं के अनुसार शेड्यूल को अनुकूलित करने के लिए लचीलापन प्रदान करते हैं। यह दृष्टिकोण उन लोगों के लिए आदर्श है जो व्यावहारिक अनुभव और स्पष्ट जानकारी चाहते हैं कि प्रत्येक भुगतान को मूलधन और ब्याज घटकों में कैसे विभाजित किया जाता है। अब, आइए एक्सेल में एक परिशोधन शेड्यूल बनाने की प्रक्रिया को चरण दर चरण तोड़ें:

⭐️ चरण 1: ऋण जानकारी और परिशोधन तालिका सेट करें

  1. नीचे दिखाए गए स्क्रीनशॉट के अनुसार संबंधित ऋण जानकारी, जैसे वार्षिक ब्याज दर, वर्षों में ऋण अवधि, प्रति वर्ष भुगतान की संख्या और ऋण राशि दर्ज करें:
  2. फिर, सेल A7:E7 में अवधि, भुगतान, ब्याज, मूलधन, शेष राशि जैसे निर्दिष्ट लेबल के साथ एक्सेल में एक परिशोधन तालिका बनाएं।
  3. अवधि कॉलम में, अवधि संख्याएँ दर्ज करें। इस उदाहरण के लिए, भुगतान की कुल संख्या 24 महीने (2 वर्ष) है, इसलिए, आप अवधि कॉलम में 1 से 24 तक संख्याएं दर्ज करेंगे। स्क्रीनशॉट देखें:
  4. एक बार जब आप लेबल और अवधि संख्याओं के साथ तालिका सेट कर लेते हैं, तो आप अपने ऋण की विशिष्टताओं के आधार पर भुगतान, ब्याज, मूलधन और शेष कॉलम के लिए सूत्र और मान दर्ज करने के लिए आगे बढ़ सकते हैं।

⭐️ चरण 2: पीएमटी फ़ंक्शन का उपयोग करके कुल भुगतान राशि की गणना करें

पीएमटी का सिंटैक्स है:

=-पीएमटी(प्रति अवधि ब्याज दर, भुगतान की कुल संख्या, उधार की राशि)
  • प्रति अवधि ब्याज दर: यदि आपके ऋण की ब्याज दर वार्षिक है, तो इसे प्रति वर्ष भुगतान की संख्या से विभाजित करें। उदाहरण के लिए, यदि वार्षिक दर 5% है और भुगतान मासिक है, तो प्रति अवधि दर 5%/12 है। इस उदाहरण में, दर B1/B3 के रूप में प्रदर्शित की जाएगी।
  • भुगतान की कुल संख्या: ऋण अवधि को वर्षों में प्रति वर्ष भुगतान की संख्या से गुणा करें। इस उदाहरण में, इसे B2*B3 के रूप में प्रदर्शित किया जाएगा।
  • ऋण की राशि: यह आपके द्वारा उधार ली गई मूल राशि है। इस उदाहरण में, यह B4 है.
  • नकारात्मक चिह्न(-): पीएमटी फ़ंक्शन एक ऋणात्मक संख्या लौटाता है क्योंकि यह एक आउटगोइंग भुगतान का प्रतिनिधित्व करता है। भुगतान को सकारात्मक संख्या के रूप में प्रदर्शित करने के लिए आप पीएमटी फ़ंक्शन से पहले एक नकारात्मक चिह्न जोड़ सकते हैं।

सेल B7 में निम्नलिखित सूत्र दर्ज करें, और फिर, इस सूत्र को अन्य कक्षों में भरने के लिए भरण हैंडल को नीचे खींचें, और आपको सभी अवधियों के लिए एक स्थिर भुगतान राशि दिखाई देगी। स्क्रीनशॉट देखें:

= -PMT($B$1/$B$3, $B$2*$B$3, $B$4)
 नोट: यहाँ, उपयोग करें पूर्ण सन्दर्भ सूत्र में ताकि जब आप इसे नीचे की कोशिकाओं में कॉपी करें, तो यह बिना किसी बदलाव के वैसा ही रहे।

⭐️ चरण 3: आईपीएमटी फ़ंक्शन का उपयोग करके ब्याज की गणना करें

इस चरण में, आप एक्सेल के आईपीएमटी फ़ंक्शन का उपयोग करके प्रत्येक भुगतान अवधि के लिए ब्याज की गणना करेंगे।

=-आईपीएमटी(प्रति अवधि ब्याज दर, विशिष्ट अवधि, भुगतान की कुल संख्या, उधार की राशि)
  • प्रति अवधि ब्याज दर: यदि आपके ऋण की ब्याज दर वार्षिक है, तो इसे प्रति वर्ष भुगतान की संख्या से विभाजित करें। उदाहरण के लिए, यदि वार्षिक दर 5% है और भुगतान मासिक है, तो प्रति अवधि दर 5%/12 है। इस उदाहरण में, दर B1/B3 के रूप में प्रदर्शित की जाएगी।
  • विशिष्ट अवधि: वह विशिष्ट अवधि जिसके लिए आप ब्याज की गणना करना चाहते हैं। यह आमतौर पर आपके शेड्यूल की पहली पंक्ति में 1 से शुरू होगा और प्रत्येक बाद की पंक्ति में 1 से बढ़ेगा। इस उदाहरण में, अवधि सेल A7 से शुरू होती है।
  • भुगतान की कुल संख्या: ऋण अवधि को वर्षों में प्रति वर्ष भुगतान की संख्या से गुणा करें। इस उदाहरण में, इसे B2*B3 के रूप में प्रदर्शित किया जाएगा।
  • ऋण की राशि: यह आपके द्वारा उधार ली गई मूल राशि है। इस उदाहरण में, यह B4 है.
  • नकारात्मक चिह्न(-): पीएमटी फ़ंक्शन एक ऋणात्मक संख्या लौटाता है क्योंकि यह एक आउटगोइंग भुगतान का प्रतिनिधित्व करता है। भुगतान को सकारात्मक संख्या के रूप में प्रदर्शित करने के लिए आप पीएमटी फ़ंक्शन से पहले एक नकारात्मक चिह्न जोड़ सकते हैं।

सेल C7 में निम्नलिखित सूत्र दर्ज करें, और फिर, इस सूत्र को भरने और प्रत्येक अवधि के लिए ब्याज प्राप्त करने के लिए भरण हैंडल को कॉलम के नीचे खींचें।

=-IPMT($B$1/$B$3, A7, $B$2*$B$3, $B$4)
 नोट: उपरोक्त सूत्र में, A7 को a के रूप में सेट किया गया है सापेक्ष संदर्भ, यह सुनिश्चित करते हुए कि यह गतिशील रूप से उस विशिष्ट पंक्ति के अनुकूल हो जाए जिस पर सूत्र विस्तारित है।

⭐️ चरण 4: पीपीएमटी फ़ंक्शन का उपयोग करके मूलधन की गणना करें

प्रत्येक अवधि के लिए ब्याज की गणना करने के बाद, परिशोधन अनुसूची बनाने में अगला कदम प्रत्येक भुगतान के मूल भाग की गणना करना है। यह पीपीएमटी फ़ंक्शन का उपयोग करके किया जाता है, जिसे निरंतर भुगतान और निरंतर ब्याज दर के आधार पर एक विशिष्ट अवधि के लिए भुगतान के मूल भाग को निर्धारित करने के लिए डिज़ाइन किया गया है।

आईपीएमटी का सिंटैक्स है:

=-पीपीएमटी(प्रति अवधि ब्याज दर, विशिष्ट अवधि, भुगतान की कुल संख्या, उधार की राशि)

पीपीएमटी फॉर्मूला के लिए सिंटैक्स और पैरामीटर पहले चर्चा किए गए आईपीएमटी फॉर्मूले में उपयोग किए गए समान हैं।

सेल D7 में निम्नलिखित सूत्र दर्ज करें, और फिर, प्रत्येक अवधि के लिए मूलधन भरने के लिए भरण हैंडल को कॉलम के नीचे खींचें। स्क्रीनशॉट देखें:

=-PPMT($B$1/$B$3, A7, $B$2*$B$3, $B$4)

⭐️ चरण 5: शेष शेष राशि की गणना करें

प्रत्येक भुगतान के ब्याज और मूलधन दोनों की गणना करने के बाद, आपके परिशोधन कार्यक्रम में अगला कदम प्रत्येक भुगतान के बाद ऋण की शेष राशि की गणना करना है। यह अनुसूची का एक महत्वपूर्ण हिस्सा है क्योंकि यह दर्शाता है कि समय के साथ ऋण शेष कैसे घटता है।

  1. अपने शेष कॉलम - E7 के पहले सेल में, निम्नलिखित सूत्र दर्ज करें, जिसका अर्थ है कि शेष शेष राशि मूल ऋण राशि से पहले भुगतान का मूल भाग घटाकर होगी: 
    =B4-D7
  2. दूसरी और सभी बाद की अवधियों के लिए, पिछली अवधि के शेष से वर्तमान अवधि के मूल भुगतान को घटाकर शेष शेष की गणना करें। कृपया निम्नलिखित सूत्र को सेल E8 में लागू करें: 
    =E7-D8
     नोट: बैलेंस सेल का संदर्भ सापेक्ष होना चाहिए, ताकि जब आप सूत्र को नीचे खींचें तो यह अपडेट हो जाए।
  3. और फिर भरण हैंडल को कॉलम तक नीचे खींचें। जैसा कि आप देख सकते हैं, प्रत्येक सेल अद्यतन मूल भुगतान के आधार पर शेष शेष राशि की गणना करने के लिए स्वचालित रूप से समायोजित हो जाएगी।

⭐️ चरण 6: ऋण सारांश बनाएं

अपना विस्तृत परिशोधन कार्यक्रम स्थापित करने के बाद, ऋण सारांश बनाने से आपके ऋण के प्रमुख पहलुओं का त्वरित अवलोकन मिल सकता है। इस सारांश में आम तौर पर ऋण की कुल लागत, भुगतान किया गया कुल ब्याज शामिल होगा।

● कुल भुगतान की गणना करने के लिए:

=SUM(B7:B30)

● कुल ब्याज की गणना करने के लिए:

=SUM(C7:C30)

⭐️ परिणाम:

अब, एक सरल लेकिन व्यापक ऋण परिशोधन कार्यक्रम सफलतापूर्वक बनाया गया है। स्क्रीनशॉट देखें:

विभिन्न अवधियों के लिए एक परिशोधन कार्यक्रम बनाएं

पिछले उदाहरण में, हम निश्चित संख्या में भुगतान के लिए ऋण चुकौती कार्यक्रम बनाते हैं। यह दृष्टिकोण किसी विशिष्ट ऋण या बंधक को संभालने के लिए एकदम सही है जहां शर्तें नहीं बदलती हैं।

लेकिन, यदि आप एक लचीली परिशोधन अनुसूची बनाना चाह रहे हैं जिसका उपयोग अलग-अलग अवधि वाले ऋणों के लिए बार-बार किया जा सकता है, जो आपको विभिन्न ऋण परिदृश्यों के लिए आवश्यक भुगतानों की संख्या को संशोधित करने की अनुमति देता है, तो आपको अधिक विस्तृत विधि का पालन करने की आवश्यकता होगी।

⭐️ चरण 1: ऋण जानकारी और परिशोधन तालिका सेट करें

  1. नीचे दिखाए गए स्क्रीनशॉट के अनुसार संबंधित ऋण जानकारी, जैसे वार्षिक ब्याज दर, वर्षों में ऋण अवधि, प्रति वर्ष भुगतान की संख्या और ऋण राशि दर्ज करें:
  2. फिर, सेल A7:E7 में अवधि, भुगतान, ब्याज, मूलधन, शेष राशि जैसे निर्दिष्ट लेबल के साथ एक्सेल में एक परिशोधन तालिका बनाएं।
  3. अवधि कॉलम में, किसी भी ऋण के लिए आपके द्वारा विचार किए जा सकने वाले भुगतानों की उच्चतम संख्या दर्ज करें, उदाहरण के लिए, 1 से 360 तक की संख्या भरें। यदि आप मासिक भुगतान कर रहे हैं तो यह मानक 30-वर्षीय ऋण को कवर कर सकता है।

⭐️ चरण 2: IF फ़ंक्शन के साथ भुगतान, ब्याज और सिद्धांत फ़ॉर्मूले को संशोधित करें

संबंधित कक्षों में निम्नलिखित सूत्र दर्ज करें, और फिर इन सूत्रों को आपके द्वारा निर्धारित भुगतान अवधि की अधिकतम संख्या तक विस्तारित करने के लिए भरण हैंडल को खींचें।

● भुगतान सूत्र:

आम तौर पर, आप भुगतान की गणना के लिए पीएमटी फ़ंक्शन का उपयोग करते हैं। IF कथन को शामिल करने के लिए, वाक्यविन्यास सूत्र है:

= IF (वर्तमान अवधि <= कुल अवधि, -पीएमटी(प्रति अवधि ब्याज दर, कुल अवधि, उधार की राशि), "" )

तो सूत्र यह है:

=IF(A7<=$B$2*$B$3, -PMT($B$1/$B$3, $B$2*$B$3, $B$4), "")

● ब्याज फार्मूला:

वाक्यविन्यास सूत्र है:

= IF (वर्तमान अवधि <= कुल अवधि, -आईपीएमटी(प्रति अवधि ब्याज दर, वर्तमान अवधि, कुल अवधि, उधार की राशि), "" )

तो सूत्र यह है:

=IF(A7<=$B$2*$B$3,-IPMT($B$1/$B$3, A7, $B$2*$B$3, $B$4), "")

● सिद्धांत सूत्र:

वाक्यविन्यास सूत्र है:

= IF (वर्तमान अवधि <= कुल अवधि, -पीपीएमटी(प्रति अवधि ब्याज दर, वर्तमान अवधि, कुल अवधि, उधार की राशि), "" )

तो सूत्र यह है:

=IF(A7<=$B$2*$B$3,-PPMT($B$1/$B$3, A7, $B$2*$B$3, $B$4), "")

⭐️ चरण 3: शेष शेष सूत्र को समायोजित करें

शेष राशि के लिए, आप आमतौर पर पिछली शेष राशि से मूलधन घटा सकते हैं। IF कथन के साथ, इसे इस प्रकार संशोधित करें:

● पहला बैलेंस सेल:(E7)

=B4-D7

● दूसरा बैलेंस सेल:(E8)

=IF(A8<=$B$2*$B$3, E7-D8, "")

⭐️ चरण 4: ऋण सारांश बनाएं

संशोधित फ़ार्मुलों के साथ परिशोधन शेड्यूल सेट करने के बाद, अगला कदम ऋण सारांश बनाना है।

● कुल भुगतान की गणना करने के लिए:

=SUM(B7:B366)

● कुल ब्याज की गणना करने के लिए:

=SUM(C7:C366)

⭐️ परिणाम:

अब, आपके पास Excel में विस्तृत ऋण सारांश के साथ एक व्यापक और गतिशील परिशोधन कार्यक्रम है। जब भी आप भुगतान अवधि की अवधि को समायोजित करते हैं, तो इन परिवर्तनों को प्रतिबिंबित करने के लिए संपूर्ण परिशोधन अनुसूची स्वचालित रूप से अपडेट हो जाएगी। नीचे डेमो देखें:

अतिरिक्त भुगतानों के साथ एक परिशोधन कार्यक्रम बनाएं

निर्धारित भुगतान से अधिक अतिरिक्त भुगतान करने से, ऋण का भुगतान अधिक तेजी से किया जा सकता है। एक परिशोधन अनुसूची जिसमें एक्सेल में बनाए जाने पर अतिरिक्त भुगतान शामिल होते हैं, यह दर्शाता है कि कैसे ये अतिरिक्त भुगतान ऋण के भुगतान में तेजी ला सकते हैं और भुगतान किए गए कुल ब्याज को कम कर सकते हैं। यहां बताया गया है कि आप इसे कैसे सेट कर सकते हैं:

⭐️ चरण 1: ऋण जानकारी और परिशोधन तालिका सेट करें

  1. नीचे दिखाए गए स्क्रीनशॉट के अनुसार संबंधित ऋण जानकारी, जैसे वार्षिक ब्याज दर, वर्षों में ऋण अवधि, प्रति वर्ष भुगतान की संख्या, ऋण राशि और अतिरिक्त भुगतान दर्ज करें:
  2. फिर, निर्धारित भुगतान की गणना करें।
    इनपुट सेल के अलावा, हमारी बाद की गणनाओं के लिए एक और पूर्वनिर्धारित सेल की आवश्यकता होती है - निर्धारित भुगतान राशि। यह ऋण पर नियमित भुगतान राशि है, यह मानते हुए कि कोई अतिरिक्त भुगतान नहीं किया गया है। कृपया निम्नलिखित सूत्र को सेल बी6 में लागू करें: 
    =IFERROR(-PMT($B$1/$B$3, $B$2*$B$3, $B$4),"")

  3. फिर, एक्सेल में एक परिशोधन तालिका बनाएं:
    • सेल A8:G8 में निर्दिष्ट लेबल सेट करें, जैसे अवधि, शेड्यूल भुगतान, अतिरिक्त भुगतान, कुल भुगतान, ब्याज, मूलधन, शेष शेष;
    • अवधि कॉलम में, किसी भी ऋण के लिए आपके द्वारा विचार किए जा सकने वाले भुगतानों की उच्चतम संख्या दर्ज करें। उदाहरण के लिए, 0 से 360 तक की संख्याएँ भरें। यदि आप मासिक भुगतान कर रहे हैं तो यह मानक 30-वर्षीय ऋण को कवर कर सकता है;
    • अवधि 0 (हमारे मामले में पंक्ति 9) के लिए, इस सूत्र के साथ शेष मान पुनः प्राप्त करें = B4, जो प्रारंभिक ऋण राशि से मेल खाती है। इस पंक्ति में अन्य सभी कक्षों को खाली छोड़ दिया जाना चाहिए।

⭐️ चरण 2: अतिरिक्त भुगतान के साथ परिशोधन अनुसूची के लिए सूत्र बनाएं

निम्नलिखित सूत्रों को संबंधित कक्षों में एक-एक करके दर्ज करें। त्रुटि प्रबंधन को बेहतर बनाने के लिए, हम इसे और भविष्य के सभी सूत्रों को IFERROR फ़ंक्शन में संलग्न करते हैं। यह दृष्टिकोण कई संभावित त्रुटियों से बचने में मदद करता है जो तब उत्पन्न हो सकती हैं जब कोई इनपुट सेल खाली छोड़ दिया जाता है या गलत मान रखता है।

● निर्धारित भुगतान की गणना करें:

सेल B10 में निम्नलिखित सूत्र दर्ज करें:

=IFERROR(IF($B$6<=G9, $B$6, G9+G9*$B$1/$B$3), "")

● अतिरिक्त भुगतान की गणना करें:

सेल C10 में निम्नलिखित सूत्र दर्ज करें:

=IFERROR(IF($B$5<G9-E10,$B$5, G9-E10), "")

● कुल भुगतान की गणना करें:

सेल D10 में निम्नलिखित सूत्र दर्ज करें:

=IFERROR(B10+C10, "")

● मूलधन की गणना करें:

सेल E10 में निम्नलिखित सूत्र दर्ज करें:

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

● ब्याज की गणना करें:

सेल F10 में निम्नलिखित सूत्र दर्ज करें:

=IFERROR(IF(B10>0, $B$1/$B$3*G9, 0), "")

● शेष राशि की गणना करें

सेल G10 में निम्नलिखित सूत्र दर्ज करें:

=IFERROR(IF(G9 >0, G9-E10-C10, 0), "")

एक बार जब आप प्रत्येक सूत्र को पूरा कर लेते हैं, तो सेल श्रेणी B10:G10 का चयन करें, और भुगतान अवधि के पूरे सेट के माध्यम से इन सूत्रों को खींचने और विस्तारित करने के लिए भरण हैंडल का उपयोग करें। उपयोग न किए गए किसी भी अवधि के लिए, सेल 0 दिखाएंगे। स्क्रीनशॉट देखें:

⭐️ चरण 3: ऋण सारांश बनाएं

● भुगतान की निर्धारित संख्या प्राप्त करें:

=B2:B3

● भुगतान की वास्तविक संख्या प्राप्त करें:

=COUNTIF(D10:D369,">"&0)

● कुल अतिरिक्त भुगतान प्राप्त करें:

=SUM(C10:C369)

● कुल ब्याज प्राप्त करें:

=SUM(F10:F369)

⭐️ परिणाम:

इन चरणों का पालन करके, आप Excel में एक गतिशील परिशोधन शेड्यूल बनाते हैं जो अतिरिक्त भुगतानों का हिसाब रखता है।

एक्सेल टेम्पलेट का उपयोग करके एक परिशोधन शेड्यूल बनाएं

टेम्पलेट का उपयोग करके Excel में परिशोधन शेड्यूल बनाना एक सीधा और समय-कुशल तरीका है। एक्सेल बिल्ट-इन टेम्प्लेट प्रदान करता है जो स्वचालित रूप से प्रत्येक भुगतान के ब्याज, मूलधन और शेष राशि की गणना करता है। यहां एक्सेल टेम्पलेट का उपयोग करके परिशोधन शेड्यूल बनाने का तरीका बताया गया है:

  1. क्लिक करें पट्टिका > नया, खोज बॉक्स में टाइप करें ऋणमुक्ति शेड्युल, और प्रेस दर्ज चाबी। फिर, उस टेम्पलेट पर क्लिक करके उसे चुनें जो आपकी आवश्यकताओं के लिए सबसे उपयुक्त हो। उदाहरण के लिए, यहां, मैं सरल ऋण कैलकुलेटर टेम्पलेट का चयन करूंगा। स्क्रीनशॉट देखें:
  2. एक बार जब आप एक टेम्पलेट चुन लें, तो पर क्लिक करें बनाएं इसे नई कार्यपुस्तिका के रूप में खोलने के लिए बटन।
  3. फिर, अपना स्वयं का ऋण विवरण दर्ज करें, टेम्पलेट को स्वचालित रूप से आपके इनपुट के आधार पर शेड्यूल की गणना और पॉप्युलेट करना चाहिए।
  4. अंत में, अपनी नई परिशोधन अनुसूची कार्यपुस्तिका सहेजें।
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Guest
Posting as Guest
×
Rate this post:
Reset
0   Characters
Suggested Locations