एक्सेल ट्यूटोरियल - विशिष्ट स्थिति के आधार पर टेक्स्ट या नंबर निकालें

कई मामलों में, आपको किसी सेल में किसी वाक्य या टेक्स्ट स्ट्रिंग से केवल उपयोगी सामग्री निकालने की आवश्यकता हो सकती है, जैसे पते से प्रांत निकालना, वाक्य से ईमेल पता निकालना, बातचीत से कूरियर बिल नंबर निकालना, और इसी तरह। यह ट्यूटोरियल सेल में एक विशिष्ट स्थिति तक निष्कर्षण को सीमित करता है और एक्सेल में विशिष्ट स्थिति के अनुसार सेल से टेक्स्ट या नंबर निकालने में मदद करने के लिए विभिन्न तरीकों को एकत्रित करता है।

---

स्थिति के अनुसार पाठ निकालें

यह अनुभाग सामान्य स्थितियों को एकत्रित करता है जहां किसी सेल से टेक्स्ट निकाला जा सकता है और चरण-दर-चरण उन्हें संभालने के लिए संबंधित तरीके प्रदान करता है। आप अधिक विवरण के लिए ब्राउज़ कर सकते हैं.

1. बाएँ या दाएँ से वर्णों की संख्या निकालें

किसी स्ट्रिंग के बाएँ या दाएँ पक्ष से वर्णों की संख्या निकालने के लिए, आप नीचे दिए गए तरीकों में से एक आज़मा सकते हैं।

1.1 सूत्रों के साथ पहले या अंतिम एन अक्षर निकालें

मान लीजिए कि आपके पास कॉलम बी में एक टेक्स्ट स्ट्रिंग सूची है जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है, प्रत्येक स्ट्रिंग से पहले 2 अक्षर और अंतिम 2 अक्षर निकालने के लिए, आप निम्नलिखित सूत्र लागू कर सकते हैं।

टेक्स्ट स्ट्रिंग से पहले N अक्षर निकालें

LEFT फ़ंक्शन Excel में टेक्स्ट स्ट्रिंग से पहले N वर्णों को आसानी से निकालने में मदद कर सकता है।

सामान्य सूत्र

=LEFT(text_string,[num_chars])

तर्क

अब आप कॉलम बी में कोशिकाओं से पहले 2 अक्षर निकालने के लिए इस सूत्र को लागू कर सकते हैं।

1. एक रिक्त कक्ष का चयन करें, नीचे दिए गए सूत्र की प्रतिलिपि बनाएँ या दर्ज करें और दबाएँ दर्ज पहला परिणाम प्राप्त करने की कुंजी. परिणाम सेल का चयन करें और अन्य सेल पर सूत्र लागू करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=LEFT(B5,2)

अब रेंज B2:B5 के प्रत्येक सेल में पहले 10 अक्षर निकाले गए हैं।

टेक्स्ट स्ट्रिंग से अंतिम N अक्षर निकालें

यहां हम एक्सेल में टेक्स्ट स्ट्रिंग से अंतिम एन अक्षर निकालने के लिए राइट फ़ंक्शन लागू करते हैं।

सामान्य सूत्र

=RIGHT(text_string,[num_chars])

तर्क

एक रिक्त कक्ष का चयन करें, नीचे दिए गए सूत्र की प्रतिलिपि बनाएँ या दर्ज करें और दबाएँ दर्ज परिणाम प्राप्त करने की कुंजी. फिर इस परिणाम सेल का चयन करें और अन्य परिणाम प्राप्त करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=RIGHT(B5,2)

1.2 एक अद्भुत टूल से पहला या अंतिम एन अक्षर निकालें

हालाँकि ऊपर दिए गए सूत्र सरल हैं, टेक्स्ट स्ट्रिंग की लंबी सूची से पहले या अंतिम n वर्णों को निकालने के लिए, आपको अभी भी ऑटोफ़िल हैंडल को ऊपर से नीचे तक खींचना होगा जिसमें थोड़ा समय लग सकता है। यहाँ अनुशंसा करता है एक्सेल के लिए कुटूलहै पाठ निकालें थोक में टेक्स्ट स्ट्रिंग की सूची से पहले या अंतिम एन वर्णों को निकालने में मदद करने के लिए उपयोगिता।

1. जिस टेक्स्ट स्ट्रिंग सूची से आप टेक्स्ट निकालना चाहते हैं उसे पहले से चुनें और क्लिक करें कुटूल > टेक्स्ट > पाठ निकालें.

2. पॉप अप में पाठ निकालें डायलॉग बॉक्स, आपको निम्नानुसार कॉन्फ़िगर करना होगा।

नोट: टेक्स्ट स्ट्रिंग बदलने पर परिणाम को गतिशील बनाने के लिए, आप जाँच कर सकते हैं सूत्र के रूप में डालें डिब्बा।

3. अगले पॉप अप में पाठ निकालें संवाद बॉक्स में, निकाले गए वर्णों को आउटपुट करने के लिए एक सेल चुनें और फिर क्लिक करें OK.

फिर निर्दिष्ट पहले या अंतिम एन अक्षर थोक में चयनित कोशिकाओं से निकाले जाते हैं।

इस सुविधा के बारे में अधिक जानने के लिए क्लिक करें।

---

2. किसी निश्चित वर्ण/शब्द के पहले या बाद में टेक्स्ट निकालें

किसी निश्चित वर्ण या शब्द के पहले या बाद में टेक्स्ट निकालने के लिए, इस अनुभाग के विभिन्न परिदृश्य आपकी आवश्यकताओं को पूरा करेंगे।

2.1 प्रथम सीमांकक (एक वर्ण) से पहले या बाद में पाठ निकालें

जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है, श्रेणी B4:B10 में प्रत्येक सेल से पहले डिलीमीटर से पहले या बाद में टेक्स्ट निकालने के लिए, आप नीचे दिए गए तरीकों में से एक को लागू कर सकते हैं।

2.1.1 सूत्र के साथ पहले सीमांकक से पहले पाठ निकालें

LEFT और FIND फ़ंक्शंस के आधार पर एक सूत्र लागू करने से सेल से पहले डिलीमीटर से पहले टेक्स्ट निकालने में मदद मिल सकती है। इसे पूरा करने के लिए आप नीचे दिए गए चरणों का पालन कर सकते हैं।

सामान्य सूत्र

=LEFT(text_string,FIND("delimiter",text_string,1)-1)

तर्क

एक रिक्त कक्ष का चयन करें, उसमें नीचे दिए गए सूत्र को कॉपी करें या दर्ज करें और दबाएँ दर्ज पहला परिणाम प्राप्त करने की कुंजी. पहले परिणाम सेल का चयन करें और अन्य सेल के पहले सीमांकक से पहले टेक्स्ट प्राप्त करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=LEFT(B5,FIND("-",B5,1)-1)

2.1.2 सूत्र के साथ पहले सीमांकक के बाद पाठ निकालें

नीचे दिया गया फॉर्मूला एक्सेल में किसी सेल से पहले डिलीमीटर के बाद टेक्स्ट को निकालने में मदद करता है।

सामान्य सूत्र

=MID(text_string,FIND("delimiter",text_string)+1,LEN(text_string))

तर्क

=MID(B5,FIND("-",B5)+1,LEN(B5))

2.1.3 एक अद्भुत टूल की मदद से पहले डिलीमीटर से पहले या बाद में टेक्स्ट निकालें

यहाँ अत्यधिक अनुशंसा करता है पाठ निकालें की उपयोगिता एक्सेल के लिए कुटूल. इस सुविधा के साथ, आप बड़ी संख्या में सेल की श्रेणी से पहले डिलीमीटर से पहले या बाद में आसानी से टेक्स्ट निकाल सकते हैं।

1. उन कक्षों की श्रेणी का चयन करें जहां से आप पाठ निकालना चाहते हैं, और फिर क्लिक करें कुटूल > टेक्स्ट > पाठ निकालें.

2। में पाठ निकालें डायलॉग बॉक्स, आपको निम्नानुसार कॉन्फ़िगर करना होगा।

नोट: टेक्स्ट स्ट्रिंग बदलने पर परिणाम को गतिशील बनाने के लिए, आप फॉर्मूला बॉक्स के रूप में सम्मिलित करें को चेक कर सकते हैं।

3. फिर दूसरा पाठ निकालें संवाद बॉक्स पॉप अप होता है, परिणाम आउटपुट करने के लिए एक सेल चुनें और क्लिक करें ठीक है.

फिर पहले सीमांकक से पहले या बाद के पाठ चयनित कोशिकाओं से एक ही बार में निकाले जाते हैं।

इस सुविधा के बारे में अधिक जानने के लिए कृपया यहां जाएं: एक्सेल में सेल से कुछ टेक्स्ट को तुरंत निकालें.

2.2 अंतिम सीमांकक (एक वर्ण) से पहले या बाद में पाठ निकालें

उपरोक्त चरणों में हमने सेल से पहले डिलीमीटर से पहले या बाद में टेक्स्ट निकालने के तरीके सीखे हैं। जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है, यह अनुभाग आपको सेल से अंतिम डिलीमीटर से पहले या बाद में टेक्स्ट निकालने के लिए दो सूत्र दिखाएगा। इसे पूरा करने के लिए आप नीचे दिए गए चरणों का पालन कर सकते हैं।

2.2.1 सूत्र के साथ अंतिम सीमांकक से पहले पाठ निकालें

किसी सेल से अंतिम डिलीमीटर से पहले टेक्स्ट निकालने के लिए, आप LEFT फ़ंक्शन के अंदर SEARCH, LEN और SUBSTITUTE फ़ंक्शन का उपयोग कर सकते हैं।

सामान्य सूत्र

=LEFT(text_string,SEARCH("#",SUBSTITUTE(text_string,"delimiter","#",LEN(text_string)-LEN(SUBSTITUTE(text_string,"delimiter",""))))-1)

तर्क

एक सेल चुनें, नीचे सूत्र दर्ज करें और दबाएँ दर्ज परिणाम प्राप्त करने की कुंजी. इस परिणाम सेल का चयन करें और उसी कॉलम में अन्य टेक्स्ट स्ट्रिंग्स से टेक्स्ट निकालने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=LEFT(B5,SEARCH("#",SUBSTITUTE(B5,"-","#",LEN(B5)-LEN(SUBSTITUTE(B5,"-",""))))-1)

2.2.2 सूत्र के साथ अंतिम सीमांकक के बाद पाठ निकालें

किसी सेल से अंतिम डिलीमीटर से पहले टेक्स्ट निकालने के बाद, आप अपनी आवश्यकतानुसार अंतिम डिलीमीटर के बाद टेक्स्ट निकालने के लिए नीचे दिया गया फॉर्मूला लागू कर सकते हैं।

सामान्य सूत्र

=RIGHT(text_string,LEN(text_string)-SEARCH("#",SUBSTITUTE(text_string,"delimiter","#",LEN(text_string)-LEN(SUBSTITUTE(text_string,"delimiter","")))))

तर्क

एक सेल चुनें, नीचे सूत्र दर्ज करें और दबाएँ दर्ज परिणाम प्राप्त करने की कुंजी. इस परिणाम सेल का चयन करें और उसी कॉलम में अन्य टेक्स्ट स्ट्रिंग्स से टेक्स्ट निकालने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=RIGHT(B5,LEN(B5)-SEARCH("#",SUBSTITUTE(B5,"-","#",LEN(B5)-LEN(SUBSTITUTE(B5,"-","")))))

2.3 nवें वर्ण के बाद पाठ निकालें

नीचे दिए गए उदाहरण को देखें, श्रेणी B4:B10 में टेक्स्ट स्ट्रिंग की एक सूची है, प्रत्येक सेल से तीसरे अक्षर के बाद टेक्स्ट निकालने के लिए, आप MID फ़ंक्शन और LEN फ़ंक्शन के आधार पर एक सूत्र लागू कर सकते हैं।

सामान्य सूत्र

=MID(text_string,nth_char+1,LEN(text_string))

तर्क

एक रिक्त कक्ष का चयन करें, उसमें नीचे दिए गए सूत्र को कॉपी करें या दर्ज करें और दबाएँ दर्ज परिणाम प्राप्त करने की कुंजी. इस परिणाम सेल का चयन करें और अन्य परिणाम प्राप्त करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=MID(B5,3+1,LEN(B5))

2.4 टेक्स्ट स्ट्रिंग से nवाँ शब्द निकालें

मान लीजिए कि आपके पास टेक्स्ट स्ट्रिंग की एक सूची है जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है, और आप टेक्स्ट स्ट्रिंग से केवल nवां शब्द निकालना चाहते हैं, तो यह अनुभाग आपको इसे पूरा करने के लिए तीन तरीके प्रदान करता है।

2.4.1 सूत्र सहित nवाँ शब्द निकालें

आप किसी सेल में टेक्स्ट स्ट्रिंग से nवां शब्द निकालने के लिए TRIM, MID, SUBSTITUTE, REPT और LEN फ़ंक्शंस को जोड़ सकते हैं।

सामान्य सूत्र

=TRIM(MID(SUBSTITUTE(text_string," ",REPT(" ",LEN((text_string))), (N-1)*LEN((text_string)+1, LEN((text_string)))

तर्क

इस मामले में, श्रेणी B5:B10 में टेक्स्ट स्ट्रिंग्स हैं, D5:D10 में nवें शब्द का प्रतिनिधित्व करने वाली संख्याएँ हैं, आइए टेक्स्ट स्ट्रिंग से nth शब्द निकालने के लिए इस सूत्र को लागू करें।

एक रिक्त कक्ष का चयन करें, उसमें नीचे दिए गए सूत्र को कॉपी करें या दर्ज करें और दबाएँ दर्ज पहला परिणाम प्राप्त करने की कुंजी. इस परिणाम सेल का चयन करें और अन्य सेल का nवाँ शब्द प्राप्त करने के लिए इसके ऑटोफ़िल हैंडल को नीचे खींचें।

=TRIM(MID(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))), (D5-1)*LEN(B5)+1, LEN(B5)))

नोट: आप सूत्र में nवाँ नंबर सीधे इस प्रकार टाइप कर सकते हैं।

=TRIM(MID(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))), (2-1)*LEN(B5)+1, LEN(B5)))

2.4.2 उपयोगकर्ता-परिभाषित फ़ंक्शन के साथ nवां शब्द निकालें

उपरोक्त सूत्र के अलावा, आप एक्सेल में किसी सेल से nवां शब्द निकालने के लिए उपयोगकर्ता-परिभाषित फ़ंक्शन भी लागू कर सकते हैं।

1। दबाएं ऑल्ट + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

2। में अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की, क्लिक करें सम्मिलित करें > मापांक, और फिर नीचे दिए गए VBA को कोड विंडो में कॉपी करें।

VBA कोड: किसी सेल में टेक्स्ट स्ट्रिंग से nवाँ शब्द निकालें

Function ExtractTheNthWord(Source As String, Position As Integer)
'Update by Extendoffice 20211202
Dim arr() As String
arr = VBA.Split(Source, " ")
xCount = UBound(arr)
If xCount < 1 Or (Position - 1) > xCount Or Position < 0 Then
    FindWord = ""
Else
    FindWord = arr(Position - 1)
End If
End Function

3। दबाएं ऑल्ट + Q बंद करने के लिए कुंजियाँ अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

4. उस वर्कशीट पर वापस जाएँ जिसमें टेक्स्ट स्ट्रिंग्स हैं जिनसे आप nवाँ शब्द निकालना चाहते हैं। एक रिक्त कक्ष का चयन करें, उसमें नीचे दिए गए सूत्र को कॉपी करें या दर्ज करें और दबाएँ दर्ज nवाँ शब्द प्राप्त करने की कुंजी।

=FindWord(B5,D5)

Or

=FindWord(B5,2)

नोट: सूत्र में, D5 वह कक्ष है जिसमें nवें शब्द को दर्शाने वाली एक संख्या है। वैकल्पिक रूप से, आप सीधे सेल संदर्भ को किसी संख्या से बदल सकते हैं।

5. परिणाम सेल का चयन करें और अन्य सेल के टेक्स्ट स्ट्रिंग से nवां शब्द निकालने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

2.4.3 एक अद्भुत उपकरण के साथ nवाँ शब्द निकालें

यदि आप ऊपर दिए गए किसी सूत्र या उपयोगकर्ता-परिभाषित फ़ंक्शन को मैन्युअल रूप से लागू नहीं करना चाहते हैं, तो यहां Excel के लिए कुटूल की अनुशंसा की गई है सेल में nवाँ शब्द निकालें उपयोगिता। इस सुविधा के साथ, आप केवल कुछ क्लिक के साथ किसी सेल में टेक्स्ट स्ट्रिंग से nवां शब्द आसानी से निकाल सकते हैं।

1. परिणाम रखने के लिए एक सेल का चयन करें और क्लिक करें कुटूल > फॉर्मूला हेल्पर > टेक्स्ट > उद्धरण सेल में nवाँ शब्द. स्क्रीनशॉट देखें:

2। में सूत्र सहायक डायलॉग बॉक्स, आपको निम्नानुसार कॉन्फ़िगर करना होगा।

3. फिर सेल B5 में टेक्स्ट स्ट्रिंग से nवां (दूसरा) शब्द निकाला जाता है, और आप देख सकते हैं कि उसी समय एक फॉर्मूला बनाया गया है। इस परिणाम सेल का चयन करें और अन्य टेक्स्ट स्ट्रिंग्स से nवां शब्द प्राप्त करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

इस सुविधा के बारे में अधिक जानने के लिए क्लिक करें।

2.5 सीमांकक की nवीं घटना से पहले या बाद में पाठ निकालें

मान लीजिए कि आपके पास टेक्स्ट स्ट्रिंग्स की एक सूची है जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है। किसी स्थान की दूसरी घटना से पहले या बाद में पाठ निकालने के लिए, यह अनुभाग इसे पूरा करने में आपकी सहायता के लिए दो सूत्र प्रदान करता है।

2.5.1 सीमांकक की nवीं घटना से पहले पाठ निकालें

आप Excel में किसी सेल से डिलीमीटर की nवीं घटना से पहले टेक्स्ट निकालने के लिए SUBSTITUTE और FIND फ़ंक्शन के साथ LEFT फ़ंक्शन का उपयोग कर सकते हैं।

सामान्य सूत्र

=LEFT(SUBSTITUTE(text_string,"delimiter",CHAR(9),n),FIND(CHAR(9),SUBSTITUTE(text_string,"delimiter",CHAR(9),n),1)-1)

तर्क

एक सेल का चयन करें, नीचे दिए गए सूत्र को कॉपी करें या दर्ज करें और दबाएँ दर्ज परिणाम प्राप्त करने की कुंजी. इस परिणाम सेल का चयन करें और सूची में अन्य परिणाम प्राप्त करने के लिए इसे ऑटोफ़िल हैंडल को नीचे खींचें।

=LEFT(SUBSTITUTE(B5," ",CHAR(9),2),FIND(CHAR(9),SUBSTITUTE(B5," ",CHAR(9),2),1)-1)

नोट: सूत्र में, B5 वह सेल है जिसमें टेक्स्ट स्ट्रिंग है जिससे आप टेक्स्ट निकालना चाहते हैं; " " यहां एक स्थान का प्रतिनिधित्व करता है और संख्या 2 एक स्थान की दूसरी घटना का प्रतिनिधित्व करता है। आप इन्हें अपनी जरूरत के हिसाब से बदल सकते हैं.

2.5.2 सीमांकक की nवीं घटना के बाद पाठ निकालें

डिलीमीटर की nवीं घटना के बाद टेक्स्ट निकालने के लिए, आप SUBSTITUTE, LEN और FIND फ़ंक्शन के साथ RIGHT फ़ंक्शन लागू कर सकते हैं।

सामान्य सूत्र

=RIGHT(SUBSTITUTE(text_string, "delimiter", CHAR(9), n), LEN(text_string)- FIND(CHAR(9), SUBSTITUTE(text_string, "delimiter", CHAR(9), n), 1) + 1)

तर्क

अब आप श्रेणी B5:B10 में प्रत्येक कक्ष से रिक्त स्थान की दूसरी घटना के बाद पाठ को निकालने के लिए इस सूत्र को निम्नानुसार लागू कर सकते हैं।

एक सेल चुनें, नीचे सूत्र दर्ज करें और दबाएँ दर्ज परिणाम प्राप्त करने की कुंजी. इस परिणाम सेल का चयन करें और अन्य परिणाम प्राप्त करने के लिए इसे ऑटोफिल हैंडल को नीचे खींचें।

=RIGHT(SUBSTITUTE(B5, " ", CHAR(9), 2), LEN(B5)- FIND(CHAR(9), SUBSTITUTE(B5, " ", CHAR(9), 2), 1) + 1)

2.6 लाइन ब्रेक से पहले या बाद में टेक्स्ट निकालें

मान लीजिए कि आपके पास कॉलम बी में एक ऑर्डर सूची है और आप प्रत्येक सेल से केवल दिनांक भाग और उत्पाद संख्या भाग निकालना चाहते हैं। इसे पूरा करने के लिए आप नीचे दिए गए एक्सेल फ़ार्मुलों का उपयोग कर सकते हैं।

2.6.1 सूत्र के साथ पहली पंक्ति के टूटने से पहले पाठ निकालें

जैसा कि आप ऊपर स्क्रीनशॉट में देख सकते हैं, दिनांक भाग सेल के भीतर पहली पंक्ति के टूटने से पहले पता लगाता है। यह अनुभाग सेल के भीतर पहली पंक्ति के टूटने से पहले टेक्स्ट निकालने में आपकी सहायता के लिए SEARCH फ़ंक्शन के साथ एक LEFT फ़ंक्शन प्रदर्शित करेगा।

सामान्य सूत्र

=LEFT(cell, SEARCH(CHAR(10), cell)-1)

तर्क

एक रिक्त कक्ष का चयन करें, उसमें नीचे दिए गए सूत्र को कॉपी करें या दर्ज करें और दबाएँ दर्ज परिणाम प्राप्त करने की कुंजी. इस परिणाम सेल का चयन करें और फिर इस फॉर्मूले को अन्य सेल पर लागू करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=LEFT(B5, SEARCH(CHAR(10), B5)-1)

फिर आप श्रेणी B5:B8 में प्रत्येक सेल में पहली पंक्ति के टूटने से पहले पाठ को देख सकते हैं जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है।

नोट: सूत्र में, CHAR(10) विंडोज़ पर एक लाइन ब्रेक का प्रतिनिधित्व करता है।

2.6.2 सूत्र के साथ अंतिम पंक्ति विराम के बाद पाठ निकालें

पिछले चरण में, हमने सेल के भीतर पहली पंक्ति के टूटने से पहले टेक्स्ट को निकालने के तरीके के बारे में बात की थी। और यह भाग आपको मार्गदर्शन करेगा कि एक अलग सूत्र के साथ सेल के भीतर अंतिम पंक्ति के विराम के बाद टेक्स्ट कैसे निकाला जाए।

सामान्य सूत्र

=TRIM(RIGHT(SUBSTITUTE(cell,CHAR(10),REPT(" ",200)),200))

तर्क

एक रिक्त कक्ष का चयन करें, नीचे दिया गया सूत्र दर्ज करें और दबाएँ दर्ज परिणाम प्राप्त करने की कुंजी. इस परिणाम सेल का चयन करें और फिर अन्य सेल पर सूत्र लागू करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=TRIM(RIGHT(SUBSTITUTE(B5,CHAR(10),REPT(" ",200)),200))

फिर उत्पाद नं. जैसा कि ऊपर स्क्रीनशॉट में दिखाया गया है, सूची में प्रत्येक सेल का हिस्सा निकाला गया है।

नोट: सूत्र में, CHAR(10) विंडोज़ पर एक लाइन ब्रेक का प्रतिनिधित्व करता है।

2.7 किसी शब्द के पहले या बाद का टेक्स्ट निकालें

पिछले भागों में, हमने सीखा कि किसी कैरेक्टर या डिलीमीटर के पहले या बाद में टेक्स्ट कैसे निकाला जाता है। पूरे शब्द के पहले या बाद में टेक्स्ट निकालने के लिए आपको क्या करना चाहिए? यह अनुभाग इस कार्य को पूरा करने में आपकी सहायता के लिए तीन विधियों का परिचय देगा।

2.7.1 सूत्र के साथ एक निश्चित शब्द से पहले पाठ निकालें

निम्नलिखित सूत्र आपको एक्सेल में सेल के भीतर एक निश्चित शब्द से पहले टेक्स्ट निकालने में मदद करता है।

सामान्य सूत्र

=IFERROR(LEFT(cell,FIND(word,cell)-1),cell)

तर्क

एक रिक्त कक्ष का चयन करें, नीचे दिया गया सूत्र दर्ज करें और दबाएँ दर्ज परिणाम प्राप्त करने की कुंजी. इस परिणाम सेल का चयन करें और फिर इस फॉर्मूले को अन्य सेल पर लागू करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

इस उदाहरण में, हम "एक्सेल" शब्द से पहले के सभी पाठ निकालने जा रहे हैं, इसलिए हम शब्द को सीधे सूत्र में टाइप करते हैं और इसे दोहरे उद्धरण चिह्नों में संलग्न करते हैं। या आप उस सेल का संदर्भ ले सकते हैं जिसमें "एक्सेल" शब्द है।

=IFERROR(LEFT(B5,FIND("Excel",B5)-1),B5)

टिप्पणियाँ:

2.7.2 सूत्र के साथ एक निश्चित शब्द के बाद पाठ निकालें

किसी निश्चित शब्द के बाद टेक्स्ट निकालने के लिए, आप इसे पूरा करने के लिए निम्नलिखित सूत्र लागू कर सकते हैं।

सामान्य सूत्र

=TRIM(MID(cell,SEARCH(word,cell)+LEN(word),255))

तर्क

एक सेल चुनें, नीचे सूत्र दर्ज करें और दबाएँ दर्ज परिणाम प्राप्त करने की कुंजी. परिणाम सेल का चयन करें और फिर इस फॉर्मूले को अन्य सेल पर लागू करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=TRIM(MID(B5,SEARCH("Excel",B5)+LEN("Excel"),255))

जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है, प्रत्येक सेल में "एक्सेल" शब्द निकाले जाने के बाद आप सभी टेक्स्ट देख सकते हैं।

टिप्पणियाँ:

2.7.3 एक अद्भुत टूल से किसी निश्चित शब्द के पहले या बाद का टेक्स्ट निकालें

यदि आपको लगता है कि फॉर्मूला का उपयोग करने से बहुत असुविधा हो सकती है, तो यहां इसकी अत्यधिक अनुशंसा की जाती है पाठ निकालें की उपयोगिता एक्सेल के लिए कुटूल. यह सुविधा कुछ ही क्लिक के साथ एक्सेल में एक्सट्रैक्शन कार्य को स्वचालित करने में मदद करती है।

1। क्लिक करें कुटूल > टेक्स्ट > पाठ निकालें इस सुविधा को सक्षम करने के लिए

2। में पाठ निकालें संवाद बॉक्स में, निम्न सेटिंग करें.

टिप्पणियाँ: यदि आप गतिशील परिणाम बनाना चाहते हैं, तो जाँच करें सूत्र के रूप में डालें डिब्बा। फिर रेंज में डेटा बदलने पर परिणाम स्वचालित रूप से अपडेट हो जाएंगे।

3. फिर एक पाठ निकालें संवाद बॉक्स पॉप अप होता है, आपको परिणाम आउटपुट करने के लिए एक सेल का चयन करना होगा और फिर क्लिक करना होगा OK बटन.

फिर चयनित श्रेणी में प्रत्येक कक्ष के भीतर एक निश्चित शब्द से पहले या बाद के पाठ तुरंत निकाले जाते हैं।

नोट: यह सुविधा केस-संवेदी है.

इस सुविधा के बारे में अधिक जानने के लिए क्लिक करें।

---

3. अक्षरों/शब्दों के बीच से निकालें

यदि आप कुछ वर्णों या शब्दों के बीच पाठ निकालना चाहते हैं, तो निम्न विधियों को आज़माएँ।

3.1 दो अक्षरों के बीच का टेक्स्ट निकालें

दो वर्णों के बीच पाठ निकालने के लिए, जो समान या भिन्न वर्ण हो सकते हैं। यह अनुभाग कई विधियाँ प्रदान करता है, और आप अपनी आवश्यकताओं के अनुसार उनमें से एक चुन सकते हैं।

3.1.1 सूत्र के साथ दो समान वर्णों के बीच पाठ निकालें

जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है, कॉलम बी में टेक्स्ट स्ट्रिंग्स की एक सूची है, और आप श्रेणी में प्रत्येक सेल से वर्ण "/" के बीच संख्या भाग निकालना चाहते हैं, निम्नलिखित सूत्र आपकी मदद कर सकता है।

एक रिक्त कक्ष का चयन करें, नीचे दिए गए सूत्र की प्रतिलिपि बनाएँ या दर्ज करें और दबाएँ दर्ज परिणाम प्राप्त करने की कुंजी. परिणाम सेल का चयन करें और फिर सूची में अन्य सेल के परिणाम प्राप्त करने के लिए इसे ऑटोफिल हैंडल को नीचे खींचें।

=SUBSTITUTE(MID(SUBSTITUTE("/" & B5&REPT(" ",6),"/",REPT(",",255)),2*255,255),",","")

फिर श्रेणी में प्रत्येक कक्ष से दो समान वर्णों "/" के बीच का पाठ निकाला जाता है। स्क्रीनशॉट देखें:

नोट:

3.1.2 सूत्र के साथ दो अलग-अलग वर्णों के बीच पाठ निकालें

किसी सेल के भीतर दो समान वर्णों के बीच टेक्स्ट निकालने का तरीका सीखने के बाद, यहां हम दो अलग-अलग वर्णों के बीच टेक्स्ट निकालने का एक सूत्र प्रदर्शित करेंगे। जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है, कॉलम बी में प्रत्येक सेल से केवल "" के बीच का ईमेल पता निकालने के लिए, आप निम्नानुसार कार्य कर सकते हैं।

सामान्य सूत्र

=MID(LEFT(cel,FIND("end_char",cell)-1),FIND("start_char",cell)+1,LEN(cell))

तर्क

एक रिक्त कक्ष का चयन करें, नीचे दिए गए सूत्र की प्रतिलिपि बनाएँ या दर्ज करें और दबाएँ दर्ज परिणाम प्राप्त करने की कुंजी. इस परिणाम सेल का चयन करें और फिर इस फॉर्मूले को अन्य सेल पर लागू करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=MID(LEFT(B5,FIND(">",B5)-1),FIND("<",B5)+1,LEN(B5))

आप देख सकते हैं कि केवल निर्दिष्ट वर्णों के बीच का टेक्स्ट निकाला गया है जैसा कि ऊपर स्क्रीनशॉट में दिखाया गया है।

3.1.3 एक अद्भुत टूल से दो अक्षरों के बीच का टेक्स्ट निकालें

यहाँ अत्यधिक अनुशंसा करता है निर्दिष्ट पाठ के बीच स्ट्रिंग निकालें का लक्षण एक्सेल के लिए कुटूल एक्सेल में एक सेल के भीतर दो समान या अलग-अलग वर्णों के बीच टेक्स्ट को आसानी से निकालने में आपकी सहायता के लिए।

1. परिणाम आउटपुट करने के लिए एक रिक्त सेल का चयन करें, और फिर क्लिक करें कुटूल > फॉर्मूला हेल्पर > फॉर्मूला हेल्पर.

2। में सूत्र सहायक संवाद बॉक्स में, निम्न सेटिंग करें.

3. फिर सेल B5 के भीतर केवल "" के बीच का टेक्स्ट निकाला जाता है। इस बीच, एक फॉर्मूला बनाया गया है, आप इस परिणाम सेल का चयन कर सकते हैं और फिर उसी सूची में अन्य सेल से टेक्स्ट निकालने के लिए इसके ऑटोफिल हैंडल को नीचे खींच सकते हैं।

इस सुविधा के बारे में अधिक जानने के लिए क्लिक करें।

3.1.4 नियम के अनुसार दो वर्णों (वर्णों सहित) के बीच का पाठ निकालें

यदि आप निकालने के बाद दो अक्षर रखना चाहते हैं, तो एक्सेल के लिए कुटूल की एक्सट्रैक्ट टेक्स्ट सुविधा में एक नियम लागू करने का प्रयास करें।

1। क्लिक करें कुटूल > टेक्स्ट > पाठ निकालें.

2। में पाठ निकालें संवाद बॉक्स में, निम्न सेटिंग करें.

3. एक और पाठ निकालें संवाद बॉक्स पॉप अप होता है, कृपया परिणाम आउटपुट करने के लिए एक सेल का चयन करें और फिर क्लिक करें OK बटन.

फिर निर्दिष्ट वर्णों (वर्णों सहित) के बीच का पाठ चयनित श्रेणी में प्रत्येक सेल से थोक में निकाला जाता है।

3.2 दो शब्दों के बीच का टेक्स्ट निकालें

दो अक्षरों के बीच टेक्स्ट निकालने के अलावा, आपको दो शब्दों के बीच टेक्स्ट निकालने की भी आवश्यकता हो सकती है। उदाहरण के लिए, कॉलम बी में प्रत्येक सेल से दो शब्दों "केटीई" और "फीचर" के बीच की सभी टेक्स्ट स्ट्रिंग निकालें जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है। इसे पूरा करने के लिए आप निम्न तरीकों में से कोई एक आज़मा सकते हैं।

3.2.1 सूत्र के साथ दो शब्दों के बीच का पाठ निकालें

आप किसी सेल के भीतर दो शब्दों के बीच की सभी टेक्स्ट स्ट्रिंग्स को निकालने के लिए MID फ़ंक्शन और SEARCH फ़ंक्शन पर आधारित सूत्र का उपयोग कर सकते हैं।

सामान्य सूत्र

=MID(cell,SEARCH("start_word",cell)+3,SEARCH("end_word",cell)-SEARCH("start_word",cell)-4)

तर्क

एक रिक्त कक्ष का चयन करें, नीचे दिए गए सूत्र की प्रतिलिपि बनाएँ या दर्ज करें और दबाएँ दर्ज परिणाम प्राप्त करने की कुंजी. इस परिणाम सेल का चयन करें और फिर इस फॉर्मूले को अन्य सेल पर लागू करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=MID(B5,SEARCH("KTE",B5)+3,SEARCH("feature",B5)-SEARCH("KTE",B5)-4)

नोट: सूत्र में, संख्या 3 शब्द "केटीई" की वर्ण लंबाई को दर्शाती है; संख्या 4 शब्द "केटीई" प्लस 1 की वर्ण लंबाई को दर्शाती है।

आप देख सकते हैं कि निर्दिष्ट दो शब्दों के बीच की सभी टेक्स्ट स्ट्रिंग्स कॉलम बी में प्रत्येक सेल से निकाली गई हैं।

3.2.2 एक अद्भुत टूल से दो शब्दों के बीच का टेक्स्ट निकालें

कई एक्सेल उपयोगकर्ताओं के लिए, सूत्रों को याद रखना और संभालना कठिन हो सकता है। के जरिए निर्दिष्ट पाठ के बीच स्ट्रिंग निकालें का लक्षण एक्सेल के लिए कुटूल, आप बस कुछ ही क्लिक से दो शब्दों के बीच का टेक्स्ट आसानी से निकाल सकते हैं।

1. परिणाम आउटपुट करने के लिए एक सेल का चयन करें और फिर क्लिक करें कुटूल > फॉर्मूला हेल्पर > सूत्र सहायक.

2। में फॉर्मूला हेल्पर डायलॉग बॉक्स, आपको निम्नानुसार कॉन्फ़िगर करना होगा।

3. फिर सेल B5 के भीतर दो शब्दों "KTE" और "फ़ीचर" के बीच की सभी टेक्स्ट स्ट्रिंग निकाली जाती हैं। इस बीच, एक फॉर्मूला बनाया गया है, आप इस परिणाम सेल का चयन कर सकते हैं और फिर उसी सूची में अन्य सेल से टेक्स्ट निकालने के लिए इसके ऑटोफिल हैंडल को नीचे खींच सकते हैं।

---

स्थिति के अनुसार संख्याएँ निकालें

अल्फ़ान्यूमेरिक स्ट्रिंग्स की सूची के लिए, तीन मामले हो सकते हैं:

1. संख्या पाठ के आरंभ में है;
2. संख्या पाठ के अंत में है;
3. संख्या पाठ में कहीं भी हो सकती है.

इस अनुभाग में, हम अलग-अलग विधियाँ प्रदान करेंगे जिनका उपयोग ऊपर उल्लिखित प्रत्येक मामले में संख्याएँ निकालने के लिए किया जा सकता है।

1 एक स्ट्रिंग के बाईं ओर से संख्या निकालें

यह भाग आपको केवल उन संख्याओं को निकालने में मदद करने के लिए एक सूत्र प्रस्तुत करेगा जो सेल में पाठ से पहले दिखाई देती हैं।

सामान्य सूत्र

=LEFT(cell, MATCH(FALSE, ISNUMBER(MID(cell, ROW(INDIRECT("1:"&LEN(cell)+1)), 1) *1), 0) -1)

तर्क

नोट:

एक रिक्त कक्ष का चयन करें, नीचे दिया गया सूत्र दर्ज करें और दबाएँ कंट्रोल + पाली + दर्ज or दर्ज परिणाम प्राप्त करने की कुंजी. इस परिणाम सेल का चयन करें और फिर अन्य सेल की संख्या प्राप्त करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=LEFT(B5, MATCH(FALSE, ISNUMBER(MID(B5, ROW(INDIRECT("1:"&LEN(B5)+1)), 1) *1), 0) -1)

टिप्पणियाँ:

---

2 एक स्ट्रिंग के दाईं ओर से संख्या निकालें

जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है, किसी सेल में टेक्स्ट के बाद दिखाई देने वाली संख्याओं को निकालने के लिए, निम्न सूत्र आज़माएँ।

सामान्य सूत्र

=RIGHT(cell, LEN(cell) - MAX(IF(ISNUMBER(MID(cell, ROW(INDIRECT("1:"&LEN(cell))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(cell))), 0)))

तर्क

नोट:

एक रिक्त कक्ष का चयन करें, नीचे दिया गया सूत्र दर्ज करें और दबाएँ कंट्रोल + पाली + दर्ज or दर्ज परिणाम प्राप्त करने की कुंजी. इस परिणाम सेल का चयन करें और फिर अन्य सेल की संख्या प्राप्त करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=RIGHT(B5, LEN(B5) - MAX(IF(ISNUMBER(MID(B5, ROW(INDIRECT("1:"&LEN(B5))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(B5))), 0)))

टिप्पणियाँ:

---

3. टेक्स्ट स्ट्रिंग में किसी भी स्थिति से सभी नंबर निकालें

उपरोक्त विधियाँ केवल टेक्स्ट स्ट्रिंग के बाएँ या दाएँ से संख्या निकालने में मदद करती हैं। यदि आप टेक्स्ट स्ट्रिंग में कहीं से भी सभी नंबर निकालना चाहते हैं, तो यहां हम इसे पूरा करने के लिए आपको तीन तरीके प्रदान करते हैं।

3.1 सूत्र के साथ एक स्ट्रिंग में कहीं से भी सभी संख्याएँ निकालें

आप एक्सेल में टेक्स्ट स्ट्रिंग में कहीं से भी सभी नंबर निकालने के लिए निम्न सूत्र लागू कर सकते हैं।

1. एक रिक्त कक्ष का चयन करें, नीचे दिए गए सूत्र की प्रतिलिपि बनाएँ या दर्ज करें और दबाएँ दर्ज सेल B5 से सभी नंबर प्राप्त करने की कुंजी।

=SUMPRODUCT(MID(0&B5, LARGE(INDEX(ISNUMBER(--MID(B5, ROW(INDIRECT("1:"&LEN(B5))), 1)) * ROW(INDIRECT("1:"&LEN(B5))), 0), ROW(INDIRECT("1:"&LEN(B5))))+1, 1) * 10^ROW(INDIRECT("1:"&LEN(B5)))/10)

2. परिणाम सेल का चयन करें और फिर अन्य सेल की सभी संख्याएं प्राप्त करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

3.2 वीबीए के साथ एक स्ट्रिंग में कहीं से भी सभी नंबर निकालें

कई एक्सेल उपयोगकर्ताओं के लिए उपरोक्त सूत्र बहुत लंबा और जटिल है। दरअसल, आप Excel में कार्य को स्वचालित करने के लिए VBA स्क्रिप्ट चला सकते हैं। आप इस प्रकार कर सकते हैं.

1। दबाएं ऑल्ट + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

2. उद्घाटन में अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की, क्लिक करें सम्मिलित करें > मॉड्यूल। फिर नीचे दिए गए VBA को मॉड्यूल कोड विंडो में कॉपी करें।

वीबीए कोड: टेक्स्ट स्ट्रिंग में कहीं से भी सभी नंबर निकालें

Sub ExtrNumbersFromRange()
'Updated by Extendoffice 20220106
    Dim xRg As Range
    Dim xDRg As Range
    Dim xRRg As Range
    Dim nCellLength As Integer
    Dim xNumber As Integer
    Dim strNumber As String
    Dim xTitleId As String
    Dim xI As Integer
    xTitleId = "KutoolsforExcel"
    Set xDRg = Application.InputBox("Please select text strings:", xTitleId, "", Type:=8)
    If TypeName(xDRg) = "Nothing" Then Exit Sub
    Set xRRg = Application.InputBox("Please select output cell:", xTitleId, "", Type:=8)
    If TypeName(xRRg) = "Nothing" Then Exit Sub
    xI = 0
    strNumber = ""
  For Each xRg In xDRg
    xI = xI + 1
    nCellLength = Len(xRg)
    For xNumber = 1 To nCellLength
      If IsNumeric(Mid(xRg, xNumber, 1)) Then
        strNumber = strNumber & Mid(xRg, xNumber, 1)
      End If
    Next xNumber
    xRRg.Item(xI) = strNumber
    strNumber = ""
  Next xRg
End Sub

3। दबाएं F5 कोड चलाने की कुंजी. उद्घाटन में KutoolsforExcel संवाद बॉक्स में, उन कक्षों की श्रेणी का चयन करें जहाँ आप प्रत्येक कक्ष से सभी संख्याएँ निकालना चाहते हैं, और फिर क्लिक करें OK बटन.

4. फिर दूसरा KutoolsforExcel संवाद बॉक्स पॉप अप होता है. इस डायलॉग बॉक्स में, एक गंतव्य सेल चुनें और क्लिक करें ठीक है.

फिर चयनित श्रेणी में प्रत्येक सेल से सभी नंबर थोक में निकाले जाते हैं।

---

4. विशिष्ट पाठ के बाद संख्याएँ निकालें

जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है, विशिष्ट पाठ "नहीं" के बाद किसी भी संख्या को निकालने के लिए, यह अनुभाग इसे पूरा करने में आपकी सहायता के लिए दो तरीके प्रदान करता है।

4.1 सूत्र के साथ किसी विशिष्ट पाठ के बाद संख्याएँ निकालें

आप Excel में किसी सेल में किसी विशिष्ट टेक्स्ट के बाद संख्याएँ निकालने के लिए निम्न सूत्र लागू कर सकते हैं।

सामान्य सूत्र:

=LOOKUP(10^6,1*MID(cell,MIN(FIND({0,1,2,3,4,5,6,7,8,9},cell&"0123456789",FIND("text"," "&cell&" "))),{2,3,4,5,6}))

तर्क

एक रिक्त कक्ष का चयन करें, नीचे दिए गए सूत्र की प्रतिलिपि बनाएँ या दर्ज करें और दबाएँ दर्ज परिणाम प्राप्त करने की कुंजी. इस परिणाम सेल का चयन करें और फिर इस फॉर्मूले को अन्य सेल पर लागू करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=LOOKUP(10^6,1*MID(B5,MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789",FIND("No."," "&B5&" "))),{2,3,4,5,6}))

टिप्पणियाँ:

4.2 उपयोगकर्ता-परिभाषित फ़ंक्शन के साथ एक विशिष्ट पाठ के बाद संख्याएँ निकालें

निम्नलिखित उपयोगकर्ता-परिभाषित फ़ंक्शन किसी सेल में किसी विशिष्ट टेक्स्ट के बाद संख्याएँ निकालने में भी मदद कर सकता है। कृपया निम्नानुसार करें.

1। दबाएं ऑल्ट + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

2। में अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की, क्लिक करें सम्मिलित करें > मापांक, और फिर नीचे दिए गए VBA कोड को मॉड्यूल कोड विंडो में कॉपी करें।

वीबीए कोड: सेल में किसी विशिष्ट टेक्स्ट के बाद संख्याएँ निकालें

Function GetNumberAfterTheChar(Rng As Range, Char As String)
'Updated by Extendoffice 20220106
Dim xValue As String
Dim xRntString As String
Dim xStart As Integer
Dim xC
    xValue = Rng.Text
    xStart = InStr(1, xValue, Char, vbTextCompare)
    If IsEmpty(xStart) Then
            GetNumberAfterTheChar = ""
            Exit Function
    End If
    If xStart < 1 Then
        GetNumberAfterTheChar = ""
        Exit Function
    End If
    xStart = xStart - 1 + Len(Char)
    If xStart < 1 Then
        GetNumberAfterTheChar = ""
        Exit Function
    End If
    xValue = Mid(xValue, xStart + 1)
    xRntString = ""
    For xI = 1 To Len(xValue)
        xC = Mid(xValue, xI, 1)
        Select Case Asc(xC)
        Case 48 To 57
            xRntString = xRntString & xC
       Case Else
            Exit For
        End Select
    Next
   GetNumberAfterTheChar = xRntString
End Function

3। दबाएं ऑल्ट + Q बंद करने के लिए कुंजियाँ अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

4. एक सेल का चयन करें, नीचे सूत्र दर्ज करें और दबाएं दर्ज चाबी। इस परिणाम सेल का चयन करें और फिर इस फॉर्मूले को अन्य सेल पर लागू करने के लिए इसके ऑटोफिल हैंडल को नीचे खींचें।

=GetNumberAfterTheChar(B5,"No. ")

टिप्पणियाँ:

---

संबंधित आलेख: