आउटलुक में ईमेल का उत्तर देते या अग्रेषित करते समय श्रेणी कैसे रखें?

लेखक: ज़ियाओयांग अंतिम संशोधित: 2018-11-21

आम तौर पर, जब आप किसी ईमेल का उत्तर देते हैं या अग्रेषित करते हैं जिसे मैंने वर्गीकृत किया है, तो भेजे गए ईमेल पर श्रेणी स्वचालित रूप से हटा दी जाएगी। यदि आप उत्तर देने या अग्रेषित करने में आउटगोइंग ईमेल पर श्रेणी रखना चाहते हैं, तो यह आलेख इससे निपटने के लिए एक विधि पेश करेगा।

वीबीए कोड के साथ ईमेल का उत्तर देते या अग्रेषित करते समय श्रेणी रखें

वीबीए कोड के साथ ईमेल का उत्तर देते या अग्रेषित करते समय श्रेणी रखें

1. नीचे पकड़ो ALT + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

2. में अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक विंडो, डबल क्लिक करें यह आउटलुक सत्र से प्रोजेक्ट1(VbaProject.OTM) मोड खोलने के लिए फलक, और फिर निम्न कोड को कॉपी करके रिक्त मॉड्यूल में पेस्ट करें।

वीबीए कोड: ईमेल का उत्तर देते या अग्रेषित करते समय श्रेणी रखें:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

दस्तावेज़ श्रेणी उत्तर 1 रखें

3. फिर इस कोड विंडो को सहेजें और बंद करें, आउटलुक को बंद करें और पुनरारंभ करें, अब, जब आप श्रेणी के साथ किसी ईमेल का उत्तर देते हैं या अग्रेषित करते हैं, तो श्रेणी को आउटगोइंग संदेश में रखा जाएगा भेजी गई आइटम, स्क्रीनशॉट देखें:

दस्तावेज़ श्रेणी उत्तर 2 रखें