आउटलुक में एकाधिक प्राप्तकर्ताओं को व्यक्तिगत रूप से कैलेंडर कैसे भेजें?

लेखक: ज़ियाओयांग अंतिम संशोधित: 2018-12-14

आम तौर पर, आप इसका उपयोग करके प्राप्तकर्ता को जल्दी और आसानी से एक कैलेंडर भेज सकते हैं ई-मेल कैलेंडर आउटलुक में सुविधा. यदि आप iCalendar फ़ाइल के रूप में संलग्न कैलेंडर को अलग-अलग कई संपर्कों को भेजना चाहते हैं, तो आपको इसे एक-एक करके भेजना होगा। इस लेख में, मैं आउटलुक में व्यक्तिगत रूप से एकाधिक प्राप्तकर्ताओं को कैलेंडर भेजने के आसान तरीके के बारे में बात करूंगा।

VBA कोड के साथ एकाधिक प्राप्तकर्ताओं को व्यक्तिगत रूप से एक कैलेंडर भेजें

VBA कोड के साथ एकाधिक प्राप्तकर्ताओं को व्यक्तिगत रूप से एक कैलेंडर भेजें

एकाधिक प्राप्तकर्ताओं को अलग-अलग कैलेंडर भेजने के लिए, निम्नलिखित VBA कोड आपकी सहायता कर सकता है, कृपया ऐसा करें:

1। पर नेविगेट करें संपर्क फलक, और उन संपर्कों का चयन करें जिन्हें आप कैलेंडर भेजना चाहते हैं।

2. फिर दबा कर रखें ALT + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

3। क्लिक करें सम्मिलित करें > मॉड्यूल, नीचे दिए गए कोड को कॉपी करके खुले हुए रिक्त मॉड्यूल में पेस्ट करें, स्क्रीनशॉट देखें:

वीबीए कोड: एकाधिक प्राप्तकर्ताओं को व्यक्तिगत रूप से एक कैलेंडर भेजें：

Sub EmailCalendarToMultiplePersonsSeparately()
Dim xSelection As Outlook.Selection
Dim xCalendarFolder As Outlook.Folder
Dim xCalendarExporter As Outlook.CalendarSharing
Dim xStartDate, xEndDate As Date
Dim xCalendarFile As String
Dim xContactItem As Outlook.ContactItem
Dim xDistListItem As Outlook.DistListItem
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xFilePath, xFileName, xEmailAddress As String
Dim xRecipient As Recipient
On Error Resume Next
xFilePath = CreateObject("WScript.Shell").SpecialFolders(16) & "\MyCalendar"
If Dir(xFilePath, vbDirectory) = "" Then MkDir xFilePath
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    MsgBox "Please Select contacts first!", vbExclamation + vbOKOnly, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection Is Nothing Then Exit Sub
Set xCalendarFolder = Outlook.Application.Session.PickFolder
If xCalendarFolder Is Nothing Then Exit Sub
If xCalendarFolder.DefaultItemType <> olAppointmentItem Then Exit Sub
Set xCalendarExporter = xCalendarFolder.GetCalendarExporter
xStartDate = InputBox("Enter the start date:", "Kutools for Outlook", "")
If Len(Trim(xStartDate)) = 0 Then Exit Sub
xEndDate = InputBox("Enter the end date:", "Kutools for Outlook", "")
If Len(Trim(xEndDate)) = 0 Then Exit Sub
If xStartDate = #1/1/4501# Or xEndDate = #1/1/4501# Then Exit Sub
xFileName = "Calendar (" & Format(xStartDate, "YYYYMMDD") & " - " & Format(xEndDate, "YYYYMMDD") & ").ics"
xCalendarFile = xFilePath & "\" & xFileName
With xCalendarExporter
    .IncludeWholeCalendar = False
    .StartDate = xStartDate
    .EndDate = xEndDate
    .CalendarDetail = olFullDetails
    .IncludeAttachments = True
    .IncludePrivateDetails = False
    .RestrictToWorkingHours = False
    .SaveAsICal xCalendarFile
End With
For Each xItem In xSelection
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        Set xMailItem = Outlook.Application.CreateItem(olMailItem)
        With xMailItem
            .To = xContactItem.Email1Address
            .Recipients.ResolveAll
            .Subject = xFileName
            .Attachments.Add xCalendarFile
            .Body = "Dear " & xContactItem.FullName & "," & vbCrLf & "Type body here..."
            .Display
        End With
    End If
    If xItem.Class = olDistributionList Then
        Set xDistListItem = xItem
        For i = 1 To xDistListItem.MemberCount
            Set xRecipient = xDistListItem.GetMember(i)
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            With xMailItem
                .To = xRecipient.AddressEntry.Address
                .Recipients.ResolveAll
                .Subject = xFileName
                .Attachments.Add xCalendarFile
                .Body = "Dear " & xRecipient.Name & "," & vbCrLf & "Type body here..."
                .Display
            End With
        Next i
    End If
Next
End Sub

4. - कोड डालने के बाद प्रेस करें F5 इस कोड को चलाने के लिए कुंजी, और a फ़ोल्डर का चयन करें संवाद बॉक्स खुल गया है, कृपया एक कैलेंडर चुनें जिसे आप भेजना चाहते हैं, स्क्रीनशॉट देखें: