आउटलुक में प्रति माह भेजे गए ईमेल की संख्या कैसे गिनें?

लेखक: ज़ियाओयांग अंतिम संशोधित: 2022-10-19

कभी-कभी, आप जानना चाहेंगे कि आपने प्रति माह कितने ईमेल भेजे हैं। यह ट्यूटोरियल आपके लिए आउटलुक में प्रति माह भेजे गए ईमेल की संख्या की गणना करने के लिए एक वीबीए कोड पेश करेगा।

वीबीए कोड के साथ आउटलुक में प्रति माह भेजे गए ईमेल की संख्या की गणना करें

कृपया प्रत्येक माह भेजे गए ईमेल की संख्या प्राप्त करने के लिए नीचे दिया गया VBA कोड लागू करें जैसा कि नीचे दिखाया गया है:

1. दबाए रखें ALT + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

2। क्लिक करें सम्मिलित करें > मॉड्यूल, और निम्नलिखित कोड को इसमें पेस्ट करें मॉड्यूल खिड़की।

वीबीए कोड: प्रति माह भेजे गए ईमेल की संख्या की गणना करें:

Dim GDictionary As Object
Sub CountSentMailsByMonth()
'Updateby Extendoffice
Dim xSentFolder As Outlook.Folder
Dim xExcelApp As Excel.Application
Dim xWb As Excel.Workbook
Dim xWs As Excel.Worksheet
Dim xMonths As Variant
Dim xItemsCount As Variant
Dim xLastRow As Integer
Dim I As Integer
Dim xAccount As Account
On Error Resume Next
Set GDictionary = CreateObject("Scripting.Dictionary")
For Each xAccount In Application.Session.Accounts
  If VBA.LCase$(xAccount.SmtpAddress) = VBA.LCase$("") Then  'Specify the Email Account
    Set xSentFolder = xAccount.DeliveryStore.GetDefaultFolder(olFolderSentMail)
    If xSentFolder.DefaultItemType = olMailItem Then
      Call ProcessFolders(xSentFolder)
    End If
  End If
Next
Set xSentFolder = Nothing
Set xExcelApp = CreateObject("Excel.Application")
xExcelApp.Visible = True
Set xWb = xExcelApp.Workbooks.Add
Set xWs = xWb.Sheets(1)
With xWs
  .Cells(1, 1) = "Month"
  .Cells(1, 2) = "Count"
  .Cells(1, 1).Font.Bold = True
  .Cells(1, 2).Font.Bold = True
  .Cells(1, 1).HorizontalAlignment = xlCenter
  .Cells(1, 2).VerticalAlignment = xlCenter
End With
xMonths = GDictionary.Keys
xItemsCount = GDictionary.Items
For I = LBound(xMonths) To UBound(xMonths)
  xLastRow = xWs.Range("A" & xWs.Rows.Count).End(xlUp).Row + 1
  With xWs
    .Cells(xLastRow, 1) = xMonths(I)
    .Cells(xLastRow, 2) = xItemsCount(I)
  End With
Next
xWs.Columns("A:B").AutoFit
xExcelApp.Visible = True
Set xExcelApp = Nothing
Set xWb = Nothing
Set xWs = Nothing
End Sub

Sub ProcessFolders(ByVal Fld As Outlook.Folder)
Dim I As Long
Dim xMail As Outlook.MailItem
Dim xMonth As String
Dim xSubFolder As Folder
On Error Resume Next
For I = Fld.Items.Count To 1 Step -1
  If Fld.Items(I).Class = olMail Then
    Set xMail = Fld.Items(I)
    xMonth = Year(xMail.SentOn) & "/" & Month(xMail.SentOn)
    If GDictionary.Exists(xMonth) Then
      GDictionary(xMonth) = GDictionary(xMonth) + 1
    Else
      GDictionary.Add xMonth, 1
    End If
  End If
Next
If Fld.Folders.Count > 0 Then
  For Each xSubFolder In Fld.Folders
    Call ProcessFolders(xSubFolder)
  Next
End If
End Sub

नोट: कोड में, कृपया ईमेल खाता बदलें"” अपने लिए.

3. अभी भी में अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की, क्लिक करें टूल्स > संदर्भ, में सन्दर्भ-परियोजना संवाद बॉक्स, जाँचें माइक्रोसॉफ्ट एक्सेल 16.0 ऑब्जेक्ट लाइब्रेरी से विकल्प उपलब्ध संदर्भ सूची बॉक्स, स्क्रीनशॉट देखें:

4। तब दबायें OK डायलॉग बॉक्स बंद करने के लिए, और दबाएँ F5 इस कोड को चलाने की कुंजी. फिर, एक एक्सेल फ़ाइल खुलेगी, जो विशिष्ट खाते के लिए प्रत्येक माह भेजे गए ईमेल की संख्या प्रदर्शित करेगी, स्क्रीनशॉट देखें: