आउटलुक में विभिन्न प्रकार के हटाए गए आइटमों को स्वचालित रूप से विभिन्न फ़ोल्डरों में कैसे स्थानांतरित करें?

लेखक: ज़ियाओयांग अंतिम संशोधित: 2022-10-19

आउटलुक में, सभी प्रकार के हटाए गए आइटम (मेल, कार्य, संपर्क, आदि) को हटाए गए आइटम फ़ोल्डर में ले जाया जाएगा। यदि आप हटाए गए आइटम फ़ोल्डर के अंतर्गत आइटम प्रकार के आधार पर आइटम को अलग-अलग फ़ोल्डर में ले जाना चाहते हैं, जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है, तो आप इसे आउटलुक में कैसे कर सकते हैं?

VBA कोड के साथ विभिन्न प्रकार के हटाए गए आइटमों को स्वचालित रूप से विभिन्न फ़ोल्डरों में ले जाएं

नीचे दिया गया VBA कोड आपको हटाए गए आइटम को स्वचालित रूप से विभिन्न फ़ोल्डरों में ले जाने में मदद कर सकता है, कृपया ऐसा करें:

1. आउटलुक लॉन्च करें और फिर दबाए रखें ALT + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

2. फिर, डबल क्लिक करें यह आउटलुक सत्र से प्रोजेक्ट-प्रोजेक्ट1 फलक, और फिर, नीचे दिए गए कोड को कॉपी करें और रिक्त कोड विंडो में पेस्ट करें:

वीबीए कोड: विभिन्न प्रकार के हटाए गए आइटमों को स्वचालित रूप से विभिन्न फ़ोल्डरों में ले जाएं

Public WithEvents GDeletedFolder As Outlook.Folder
Public WithEvents GDeletedItems As Outlook.Items
Private Sub Application_Startup()
  Set GDeletedFolder = Application.Session.GetDefaultFolder(olFolderDeletedItems)
  Set GDeletedItems = GDeletedFolder.Items
End Sub
Private Sub GDeletedItems_ItemAdd(ByVal Item As Object)
'Updateby ExtendOffice
Dim xTargetFolder As Outlook.Folder
On Error Resume Next
Select Case TypeName(Item)
  Case "MailItem", "PostItem", "ReportItem", "MeetingItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Mails")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Mails", olFolderInbox)
    End If
  Case "AppointmentItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Appointments")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Appointments", olFolderCalendar)
    End If
  Case "ContactItem", "DistListItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Contacts")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Contacts", olFolderContacts)
    End If
  Case "TaskItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Tasks")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Tasks", olFolderTasks)
    End If
  Case "JournalItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Journals")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Journals", olFolderJournal)
    End If
  Case "NoteItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Notess")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Notess", olFolderNotes)
    End If
End Select
If xTargetFolder Is Nothing Then Exit Sub
Item.Move xTargetFolder
Set xTargetFolder = Nothing
End Sub

3. फिर, इस कोड को सहेजें, और इस कोड को सक्रिय करने के लिए आउटलुक को पुनरारंभ करें।

4. अब से, जब आप कोई आइटम हटाते हैं, तो उसे नीचे दिए गए संबंधित प्रकार के फ़ोल्डर में ले जाया जाएगा हटाए गए आइटम फ़ोल्डर स्वचालित रूप से.

5. परिणाम देखने के लिए कृपया क्लिक करें फ़ोल्डर फलक के नीचे आइकन पर क्लिक करें और फिर क्लिक करें फ़ोल्डर फलक में सभी फ़ोल्डरों का विस्तार करने के लिए स्क्रीनशॉट देखें: