आउटलुक में एक या अधिक ईमेल से प्रेषक का ईमेल पता कैसे प्राप्त करें?

लेखक: सिलुविया अंतिम संशोधित: 2022-07-20

क्या आपने कभी आउटलुक में एक या अधिक प्राप्त ईमेल के "प्रेषक" फ़ील्ड से ईमेल पता निकालने का प्रयास किया है? यह आलेख इस कार्य को संभालने में आपकी सहायता के लिए एक VBA कोड प्रदान करता है।

आउटलुक में एक या अधिक ईमेल से प्रेषक का ईमेल पता प्राप्त करें

आउटलुक में एक या अधिक प्राप्त ईमेल के "प्रेषक" फ़ील्ड से ईमेल पता निकालने के लिए कृपया निम्नलिखित वीबीए कोड चलाएं।

1. एक ईमेल फ़ोल्डर खोलें, एक ईमेल संदेश चुनें जिससे आप प्रेषक का ईमेल पता प्राप्त करना चाहते हैं। दबाओ ऑल्ट + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

टिप्स: एकाधिक ईमेल का चयन करने के लिए कृपया इसे दबाए रखें कंट्रोल कुंजी और फिर एक-एक करके ईमेल का चयन करें।

2। में अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की, क्लिक करें सम्मिलित करें > मॉड्यूल, फिर निम्नलिखित VBA कोड को मॉड्यूल (कोड) विंडो में कॉपी करें।

वीबीए कोड: आउटलुक में एक या अधिक ईमेल से प्रेषक का ईमेल पता निकालें

Sub GetSmtpAddressOfSelectionEmail()
  Dim xExplorer As Explorer
  Dim xSelection As Selection
  Dim xItem As Object
  Dim xMail As MailItem
  Dim xAddress As String
  Dim xFldObj As Object
  Dim FilePath As String
  Dim xFSO As Scripting.FileSystemObject
  On Error Resume Next
  Set xExplorer = Application.ActiveExplorer
  Set xSelection = xExplorer.Selection
  For Each xItem In xSelection
    If xItem.Class = olMail Then
      Set xMail = xItem
      xAddress = xAddress & VBA.vbCrLf & "  " & GetSmtpAddress(xMail)
    End If
  Next
  If MsgBox("Sender SMTP Address is: " & xAddress & vbCrLf & vbCrLf & "Do you want to export the address list to a txt file? ", vbYesNo, "Kutools for Outlook") = vbYes Then
    Set xFldObj = CreateObject("Shell.Application").BrowseforFolder(0, "Select a Folder", 0, 16)
    Set xFSO = New Scripting.FileSystemObject
    If xFldObj Is Nothing Then Exit Sub
    FilePath = xFldObj.Items.Item.Path & "\Address.txt"
    Close #1
    Open FilePath For Output As #1
    Print #1, "Sender SMTP Address is: " & xAddress
    Close #1
    Set xFSO = Nothing
    Set xFldObj = Nothing
    MsgBox "Address list has been exported to：" & FilePath, vbOKOnly + vbInformation, "Kutools for Outlook"
  End If
End Sub
Function GetSmtpAddress(Mail As MailItem)
  Dim xNameSpace As Outlook.NameSpace
  Dim xEntryID As String
  Dim xAddressEntry As AddressEntry
  Dim PR_SENT_REPRESENTING_ENTRYID As String
  Dim PR_SMTP_ADDRESS As String
  Dim xExchangeUser As exchangeUser
  On Error Resume Next
  GetSmtpAddress = ""
  Set xNameSpace = Application.Session
  If Mail.sender.Type <> "EX" Then
    GetSmtpAddress = Mail.sender.Address
  Else
    PR_SENT_REPRESENTING_ENTRYID = "http://schemas.microsoft.com/mapi/proptag/0x00410102"
    xEntryID = Mail.PropertyAccessor.BinaryToString(Mail.PropertyAccessor.GetProperty(PR_SENT_REPRESENTING_ENTRYID))
    Set xAddressEntry = xNameSpace.GetAddressEntryFromID(xEntryID)
    If xAddressEntry Is Nothing Then Exit Function
    If xAddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Or xAddressEntry.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then
      Set xExchangeUser = xAddressEntry.GetExchangeUser()
      If xExchangeUser Is Nothing Then Exit Function
      GetSmtpAddress = xExchangeUser.PrimarySmtpAddress
    Else
      PR_SMTP_ADDRESS = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
      GetSmtpAddress = xAddressEntry.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
    End If
  End If
End Function

3। क्लिक करें टूल्स > संदर्भ, तो जाँच करें माइक्रोसॉफ्ट स्क्रिप्टिंग रनटाइम इन बॉक्स सन्दर्भ - प्रोजेक्ट1 संवाद बॉक्स।

4। दबाएं F5 कोड चलाने की कुंजी. फिर एक आउटलुक के लिए कुटूल संवाद बॉक्स पॉप अप होता है, जिसमें चयनित ईमेल के सभी प्रेषकों के ईमेल पते सूचीबद्ध होते हैं।

टिप्स:

यदि आपको पता सूची को txt फ़ाइल में निर्यात करने की आवश्यकता है, तो क्लिक करें हाँ बटन.

या क्लिक करें नहीं प्रक्रिया समाप्त करने के लिए बटन।

5. क्लिक करने के बाद हाँ बटन, ए फ़ोल्डर के लिए ब्राउज़ संवाद बॉक्स पॉप अप होता है. कृपया फ़ाइल को सहेजने के लिए एक फ़ोल्डर चुनें और क्लिक करें OK बटन.