आउटलुक से सभी श्रेणियां कैसे साफ़ करें?

लेखक: ज़ियाओयांग अंतिम संशोधित: 2018-11-29

मान लीजिए, आपके आउटलुक में रंग श्रेणी में बहुत सारे आइटम लागू होते हैं। यदि आपको इन सभी श्रेणियों को आइटम से साफ़ करने की आवश्यकता है, तो आप आउटलुक में इस काम को जल्दी और आसानी से कैसे निपटा सकते हैं?

सभी श्रेणियाँ साफ़ करें सुविधा के साथ एक विशिष्ट फ़ोल्डर से सभी श्रेणियां साफ़ करें

वीबीए कोड के साथ एक विशिष्ट खाते से सभी श्रेणियां साफ़ करें

सभी श्रेणियाँ साफ़ करें सुविधा के साथ एक विशिष्ट फ़ोल्डर से सभी श्रेणियां साफ़ करें

यदि आपको किसी विशिष्ट फ़ोल्डर में श्रेणियां साफ़ करने की आवश्यकता है, तो कृपया ऐसा करें:

1. उस फ़ोल्डर पर क्लिक करें जिससे आप रंग श्रेणियाँ हटाना चाहते हैं, और फिर दबाएँ Ctrl + एक सभी वस्तुओं का चयन करने के लिए.

2. फिर राइट क्लिक करें और फिर चुनें श्रेणीबद्ध करना > सभी श्रेणियों को साफ़ करें संदर्भ मेनू से, स्क्रीनशॉट देखें:

दस्तावेज़ स्पष्ट श्रेणी 1

3. और फिर, इस विशिष्ट फ़ोल्डर में सभी रंग श्रेणियां एक ही बार में साफ़ कर दी गई हैं।

वीबीए कोड के साथ एक विशिष्ट खाते से सभी श्रेणियां साफ़ करें

किसी खाते से सभी आइटमों, जैसे ईमेल, कार्य, संपर्क, नोट्स इत्यादि से सभी श्रेणियों को साफ़ करने के लिए, नीचे दिया गया VBA कोड आपकी मदद कर सकता है:

1. उस खाते के ईमेल पर क्लिक करें जिससे आप सभी श्रेणियां साफ़ करना चाहते हैं, फिर उसे दबाए रखें ALT + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

2। क्लिक करें सम्मिलित करें > मॉड्यूल, और निम्नलिखित मैक्रो को इसमें पेस्ट करें मॉड्यूल खिड़की।

वीबीए कोड: किसी विशिष्ट खाते से सभी श्रेणियां साफ़ करें:

Sub BatchClearAllCategories_AllOutlookItems()
    Dim xCurrentFolder As Outlook.Folder
    Dim xFolder As Folder, xCurFolder As Folder
    Dim xPos As Integer
    Dim xRootFldName As String
    Set xCurFolder = Outlook.ActiveExplorer.CurrentFolder
    xPos = InStr(3, xCurFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = Mid(xCurFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = Mid(xCurFolder.FolderPath, 3, Len(xCurFolder.FolderPath) - 2)
    End If
    Set xCurrentFolder = Outlook.Application.Session.Folders(xRootFldName)
    For Each xFolder In xCurrentFolder.Folders
        Call ProcessFolders(xFolder)
    Next
    MsgBox "Clear completed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub
Sub ProcessFolders(ByVal CurFld As Outlook.Folder)
    Dim xItem As Object
    Dim i As Integer
    Dim xSubfolder As Outlook.Folder
    If CurFld.Items.Count > 0 Then
        For i = CurFld.Items.Count To 1 Step -1
            Set xItem = CurFld.Items.Item(i)
            xItem.Categories = ""
            xItem.Save
        Next
    End If
    If CurFld.Folders.Count = 0 Then Exit Sub
    For Each xSubfolder In CurFld.Folders
        Call ProcessFolders(xSubfolder)
    Next
End Sub

3। फिर दबायें F5 इसे चलाने के लिए कुंजी, और फिर आपको याद दिलाने के लिए एक प्रॉम्प्ट बॉक्स पॉप आउट होता है कि चयनित खाते से सभी श्रेणियां साफ़ कर दी गई हैं, स्क्रीनशॉट देखें:

दस्तावेज़ स्पष्ट श्रेणी 2