आउटलुक में भेजी गई मीटिंग को किसी विशिष्ट फ़ोल्डर में स्वचालित रूप से कैसे स्थानांतरित करें?

लेखक: ज़ियाओयांग अंतिम संशोधित: 2018-11-29

आम तौर पर, ईमेल या मीटिंग भेजने के बाद, वे दोनों भेजे गए आइटम फ़ोल्डर में स्थित होंगे। तो, भेजे गए आइटम फ़ोल्डर काफी गन्दा और बोझिल हो जाएगा। इस लेख में, मैं मीटिंग भेजे जाने के बाद भेजी गई मीटिंग को स्वचालित रूप से किसी अन्य फ़ोल्डर में ले जाने की एक विधि पेश करूंगा।

भेजी गई मीटिंगों को स्वचालित रूप से VBA कोड वाले एक विशिष्ट फ़ोल्डर में ले जाएँ

भेजी गई मीटिंगों को स्वचालित रूप से VBA कोड वाले एक विशिष्ट फ़ोल्डर में ले जाएँ

सभी भेजे गए मीटिंग आमंत्रणों को स्वचालित रूप से किसी अन्य फ़ोल्डर में ले जाने के लिए, निम्नलिखित कोड आपकी सहायता कर सकता है, कृपया ऐसा करें:

1. दबाए रखें ALT + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

2. में अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक विंडो, डबल क्लिक करें यह आउटलुक सत्र से प्रोजेक्ट1(VbaProject.OTM) मोड खोलने के लिए फलक, और फिर निम्न कोड को कॉपी करके रिक्त मॉड्यूल में पेस्ट करें।

वीबीए कोड: भेजी गई मीटिंग को स्वचालित रूप से एक विशिष्ट फ़ोल्डर में ले जाएं

Private WithEvents GExplorer As Outlook.Explorer
Public WithEvents GSentFolder As Outlook.Folder
Public WithEvents GSentItems As Outlook.Items
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
Dim xFolder As Folder, xRootFolder As Folder
Dim xRootFldName As String
Dim xPos As Integer
    On Error Resume Next
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    xPos = VBA.InStr(3, xFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, Len(xFolder.FolderPath) - 2)
    End If
    Set xRootFolder = Outlook.Application.Session.Folders(xRootFldName)
    Set GSentFolder = xRootFolder.Folders("Sent Items")
    Set GSentItems = GSentFolder.Items
End Sub
Private Sub GSentItems_ItemAdd(ByVal Item As Object)
    Dim xMeetingItem As Outlook.MeetingItem
    Dim xTargetFolder As Outlook.Folder
    On Error Resume Next
    If Item.Class <> olMeetingRequest Then Exit Sub
    Set xMeetingItem = Item
    Set xTargetFolder = GSentFolder.Folders("Meetings")
    If xTargetFolder Is Nothing Then
        Set xTargetFolder = GSentFolder.Folders.Add("Meetings")
    End If
    xMeetingItem.Move xTargetFolder
End Sub

दस्तावेज़ चाल भेजा गया मीटिंग 1

3. फिर, कोड विंडो सहेजें और बंद करें। अब, जब कोई मीटिंग ईमेल भेजा जाता है, तो उसे नाम के एक नए फ़ोल्डर में ले जाया जाएगा बैठक नीचे भेजी गई आइटम फ़ोल्डर स्वचालित रूप से, स्क्रीनशॉट देखें:

दस्तावेज़ चाल भेजा गया मीटिंग 2