आउटलुक से भेजे गए आइटम फ़ोल्डर में सामान्य रूप से उत्तर कैसे दें?

लेखक: ज़ियाओयांग अंतिम संशोधित: 2018-11-14

आम तौर पर, जब आप अपने द्वारा भेजे गए लोगों के लिए एक और अतिरिक्त संदेश भेजने के लिए भेजे गए आइटम फ़ोल्डर में उत्तर सुविधा पर क्लिक करते हैं, तो आपका अपना ईमेल पता निम्न स्क्रीनशॉट के अनुसार To फ़ील्ड में प्रदर्शित किया जाएगा। हर बार पता बदलना आपके लिए कष्टप्रद हो सकता है। आउटलुक आपके बजाय मूल प्राप्तकर्ता के पते का उपयोग कैसे कर सकता है?

दस्तावेज़ उत्तर भेजा गया ईमेल 1

सभी उत्तर सुविधा के साथ आउटलुक से भेजे गए आइटम फ़ोल्डर में सामान्य रूप से उत्तर दें

वीबीए कोड के साथ आउटलुक से भेजे गए आइटम फ़ोल्डर में सामान्य रूप से उत्तर दें

सभी उत्तर सुविधा के साथ आउटलुक से भेजे गए आइटम फ़ोल्डर में सामान्य रूप से उत्तर दें

आउटलुक में, सभी को उत्तर दें यह सुविधा इस समस्या को हल करने में आपकी सहायता कर सकती है, कृपया ऐसा करें:

जब आपको मूल प्राप्तकर्ता का पता रखने के लिए दोबारा भेजने के लिए भेजे गए ईमेल का उत्तर देने की आवश्यकता हो, तो कृपया क्लिक करें सभी को उत्तर दें बटन, और मूल प्राप्तकर्ता का पता स्थित है सेवा मेरे निम्नलिखित स्क्रीनशॉट के रूप में फ़ील्ड दिखाया गया है:

दस्तावेज़ उत्तर भेजा गया ईमेल 2

वीबीए कोड के साथ आउटलुक से भेजे गए आइटम फ़ोल्डर में सामान्य रूप से उत्तर दें

कभी-कभी, आप भूल सकते हैं सभी को उत्तर दें भेजे गए संदेश का उत्तर देते समय सुविधा, इसलिए नीचे दिया गया VBA कोड आपको उत्तर सुविधा का उपयोग करके भेजे गए आइटम फ़ोल्डर में सामान्य रूप से उत्तर देने में मदद कर सकता है। निम्नलिखित चरणों के साथ करें:

1. दबाए रखें ALT + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

2. में अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक विंडो, डबल क्लिक करें यह आउटलुक सत्र से प्रोजेक्ट1(VbaProject.OTM) मोड खोलने के लिए फलक, और फिर निम्न कोड को कॉपी करके रिक्त मॉड्यूल में पेस्ट करें।

वीबीए कोड: आउटलुक से भेजे गए आइटम फ़ोल्डर में सामान्य रूप से उत्तर दें:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

दस्तावेज़ उत्तर भेजा गया ईमेल 3

3. फिर, कोड को सहेजें, और क्लिक करते समय, कोड प्रभाव लेने के लिए आउटलुक को पुनरारंभ करें जवाब दें ईमेल पुनः भेजने के लिए भेजी गई आइटम फ़ोल्डर में, मूल प्राप्तकर्ता का पता आपकी आवश्यकता के अनुसार To फ़ील्ड में प्रदर्शित होता है।