आउटलुक में श्रेणी के आधार पर कार्यों को कैसे प्रिंट करें?

लेखक: ज़ियाओयांग अंतिम संशोधित: 2018-10-22

मान लीजिए, आपके आउटलुक कार्यों में विभिन्न रंग श्रेणियां हैं, और अब, आप विभिन्न पृष्ठों में श्रेणियों के आधार पर कार्यों की सूची प्रिंट करना चाहते हैं। आप आउटलुक में इस कार्य को कैसे हल कर सकते हैं?

विभिन्न पृष्ठों में श्रेणियों के आधार पर कार्यों को एक-एक करके मैन्युअल रूप से प्रिंट करें

वीबीए कोड के साथ विभिन्न पृष्ठों में श्रेणियों के आधार पर कार्यों को प्रिंट करें

विभिन्न पृष्ठों में श्रेणियों के आधार पर कार्यों को एक-एक करके मैन्युअल रूप से प्रिंट करें

आउटलुक में, आप विभिन्न श्रेणियों के आधार पर कार्यों को एक-एक करके विभिन्न पृष्ठों में मैन्युअल रूप से प्रिंट कर सकते हैं, कृपया ऐसा करें:

1. आउटलुक लॉन्च करें, और टास्क फलक पर जाएं और उस कार्य फ़ोल्डर का चयन करें जिसे आप प्रिंट करना चाहते हैं, और फिर दबाएँ Ctrl + ई को सक्रिय करने के लिए Search बॉक्स, और फिर के नीचे Search टैब पर क्लिक करें वर्गीकृत किया आइकन, और एक रंग श्रेणी चुनें जिसे आपको प्रिंट करना है, स्क्रीनशॉट देखें:

श्रेणी 1 के अनुसार दस्तावेज़ प्रिंट कार्य

2. और फिर, विशिष्ट रंग श्रेणी वाले सभी कार्य एक साथ सूचीबद्ध होते हैं, स्क्रीनशॉट देखें:

श्रेणी 2 के अनुसार दस्तावेज़ प्रिंट कार्य

3. फिर क्लिक करते जाइये पट्टिका > छाप दिखाए गए स्क्रीनशॉट के अनुसार इस कार्य सूची को प्रिंट करने के लिए:

श्रेणी 3 के अनुसार दस्तावेज़ प्रिंट कार्य

4. अन्य रंग श्रेणियों के साथ कार्यों की सूचियों को एक-एक करके मैन्युअल रूप से प्रिंट करने के लिए उपरोक्त चरणों को दोहराएं।

वीबीए कोड के साथ विभिन्न पृष्ठों में श्रेणियों के आधार पर कार्यों को प्रिंट करें

यहां एक वीबीए कोड है जो आपको श्रेणी के आधार पर कार्यों को एक साथ विभिन्न पृष्ठों में प्रिंट करने में मदद कर सकता है, कृपया निम्नलिखित चरणों का पालन करें:

1। इस पर जाएं कार्य फलक और उस कार्य फ़ोल्डर का चयन करें जिसे आप प्रिंट करना चाहते हैं।

2. फिर, दबाए रखें ALT + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

3. और फिर, क्लिक करें सम्मिलित करें > मॉड्यूल, खुले हुए रिक्त मॉड्यूल में नीचे दिए गए कोड को कॉपी और पेस्ट करें:

वीबीए कोड: विभिन्न पृष्ठों में श्रेणियों के आधार पर कार्यों को प्रिंट करें:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4। तब दबायें टूल्स > संदर्भ में अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की, बाहर निकली हुई सन्दर्भ-परियोजना1 संवाद बॉक्स, जाँचें माइक्रोसॉफ्ट एक्सेल ऑब्जेक्ट लाइब्रेरी और माइक्रोसॉफ्ट स्क्रिप्टिंग रनटाइम से विकल्प उपलब्ध संदर्भ सूची बॉक्स, स्क्रीनशॉट देखें:

श्रेणी 4 के अनुसार दस्तावेज़ प्रिंट कार्य

5. और फिर, क्लिक करें OK बटन, अब, दबाएँ F5 इस कोड को चलाने के लिए कुंजी, कोड समाप्त होने के बाद, विभिन्न श्रेणियों वाले कार्यों की सूची अलग-अलग पृष्ठों में मुद्रित की जाएगी।