आउटलुक में विशिष्ट अनुलग्नक के आधार पर ईमेल को स्वचालित रूप से कैसे फ़्लैग करें?

लेखक: ज़ियाओयांग अंतिम संशोधित: 2018-10-22

विशिष्ट महत्वपूर्ण अनुलग्नक के साथ कुछ ईमेल प्राप्त करते समय, आपको उन्हें फ़्लैग करने की आवश्यकता हो सकती है, ताकि, आप उन्हें फ़्लो-अप के लिए जल्दी और आसानी से ढूंढ सकें। इस लेख में, मैं उन ईमेल को स्वचालित रूप से चिह्नित करने के आसान तरीके के बारे में बात करूंगा जो विशिष्ट नामों के साथ संलग्न हैं।

VBA कोड के साथ विशिष्ट अनुलग्नक के आधार पर ईमेल को स्वचालित रूप से फ़्लैग करें

VBA कोड के साथ विशिष्ट अनुलग्नक के आधार पर ईमेल को स्वचालित रूप से फ़्लैग करें

विशिष्ट अनुलग्नक वाले ईमेल को ऑटो फ़्लैग करने के लिए, कृपया निम्नलिखित VBA कोड लागू करें:

1. आउटलुक लॉन्च करें, और फिर दबाए रखें ALT + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

2. में अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक विंडो, डबल क्लिक करें यह आउटलुक सत्र से प्रोजेक्ट1(VbaProject.OTM) एक नया मोड खोलने के लिए फलक, और फिर निम्न कोड को कॉपी करके रिक्त मॉड्यूल में पेस्ट करें।

वीबीए कोड: विशिष्ट अनुलग्नक के आधार पर ईमेल को ऑटो फ़्लैग करें:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"  'Add the file extension as you need
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then 'Change the text of the attachment name
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

नोट: उपरोक्त कोड में, आप फ़ाइल एक्सटेंशन और अटैचमेंट फ़ाइल नाम को अपनी आवश्यकता के अनुसार बदल सकते हैं।

3. फिर कोड को सहेजें, और कोड को प्रभावी बनाने के लिए आउटलुक को पुनः आरंभ करें, अब, ईमेल प्राप्त करते समय, अनुलग्नकों के नामों में निर्दिष्ट पाठ शामिल है, आउटलुक फॉलो-अप के लिए इस ईमेल को स्वचालित रूप से ध्वजांकित करेगा, स्क्रीनशॉट देखें: