आउटलुक में उत्तरों और फॉरवर्ड के लिए अलग-अलग हस्ताक्षर कैसे सेट करें?

लेखक: ज़ियाओयांग अंतिम संशोधित: 2018-08-20

आम तौर पर, आप अपने आउटलुक में अलग-अलग खातों के लिए अलग-अलग हस्ताक्षर सेट कर सकते हैं, लेकिन, क्या आपने कभी उत्तर और अग्रेषण के लिए अलग-अलग हस्ताक्षर लागू करने का प्रयास किया है। इसका मतलब है, जब आप किसी ईमेल का उत्तर देते हैं, तो हस्ताक्षर1 डाला जाता है, जब आप किसी ईमेल को अग्रेषित करते हैं तो हस्ताक्षर2 लगाया जाता है। आप आउटलुक में इस कार्य को कैसे हल कर सकते हैं?

VBA कोड के साथ उत्तरों और अग्रेषण के लिए अलग-अलग हस्ताक्षर सेट करें

VBA कोड के साथ उत्तरों और अग्रेषण के लिए अलग-अलग हस्ताक्षर सेट करें

निम्नलिखित वीबीए कोड आपको उत्तर और अग्रेषण के लिए अलग-अलग हस्ताक्षर सेट करने में मदद कर सकता है, कृपया नीचे दिए गए चरणों को एक-एक करके करें:

1. दबाए रखें ALT + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

2। तब दबायें सम्मिलित करें > मॉड्यूल, नीचे दिए गए कोड को कॉपी करके खुले हुए रिक्त मॉड्यूल में पेस्ट करें, स्क्रीनशॉट देखें:

वीबीए कोड: उत्तर और अग्रेषण के लिए अलग-अलग हस्ताक्षर सेट करें:

Public WithEvents GExplorer As Outlook.Explorer
Public WithEvents GMail As Outlook.MailItem
Public GFSO As Scripting.FileSystemObject
Public GTextStream As Scripting.TextStream
Public GText As String
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
    Set GFSO = New Scripting.FileSystemObject
End Sub
Private Sub GExplorer_SelectionChange()
    Dim xItem As Object
    On Error Resume Next
    Set xItem = GExplorer.Selection.Item(1)
    If xItem.Class <> olMail Then Exit Sub
    Set GMail = xItem
End Sub
Private Sub GMail_Reply(ByVal Response As Object, Cancel As Boolean)
    InsertSignature Response, "Signature1.htm"   'change this signature name for replies
End Sub
Private Sub GMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    InsertSignature Forward, " Signature2.htm"    'change this signature name for forwards
End Sub
Private Sub InsertSignature(Item As Object, SignName As String)
    Dim xSignatureFile As String
    Dim xMailItem As Outlook.MailItem
    xSignatureFile = CreateObject("WScript.Shell").SpecialFolders(5)
    xSignatureFile = xSignatureFile & "\Microsoft\Signatures\" & SignName
    Set GTextStream = GFSO.OpenTextFile(xSignatureFile)
    GText = ""
    GText = GTextStream.ReadAll
    If Item.Class <> olMail Then Exit Sub
    Set xMailItem = Item
    With xMailItem
        .Display
        .HTMLBody = .HTMLBody & "<br><br>" & GText
    End With
End Sub

नोट: उपरोक्त कोड में, हस्ताक्षर 1 और हस्ताक्षर 2 ये दो हस्ताक्षर नाम हैं जिनका उपयोग आप उत्तर देने और अग्रेषित करने के लिए करना चाहते हैं। कृपया अपनी आवश्यकता के अनुसार नाम बदलें।

उत्तर 1 के लिए डॉक्टर का हस्ताक्षर

3. अभी भी में अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की, क्लिक करें टूल्स > संदर्भ पर जाने के लिए सन्दर्भ-परियोजना1 संवाद बॉक्स, और जाँचें माइक्रोसॉफ्ट स्क्रिप्टिंग रनटाइम से विकल्प उपलब्ध संदर्भ सूची बॉक्स, स्क्रीनशॉट देखें:

उत्तर 2 के लिए डॉक्टर का हस्ताक्षर