दस्तावेज़ को मैन्युअल रूप से कई दस्तावेज़ों में विभाजित करने के बजाय, यह विधि Word दस्तावेज़ को Word में निर्दिष्ट सीमांकक द्वारा विभाजित करने के लिए एक VBA प्रस्तुत करेगी। कृपया इस प्रकार करें:

1। दबाएँ ऑल्ट + F11 एप्लिकेशन विंडो के लिए Microsoft Visual Basic खोलने के लिए कुंजियाँ एक साथ;

2। क्लिक करें सम्मिलित करें > मॉड्यूल, और फिर नई खुलने वाली मॉड्यूल विंडो में नीचे VBA कोड चिपकाएँ।

वीबीए: डिलीमीटर द्वारा वर्ड दस्तावेज़ को एकाधिक दस्तावेज़ों में विभाजित करें

Sub SplitNotes(delim As String, strFilename As String)
Dim doc As Document
Dim arrNotes
Dim I As Long
Dim X As Long
Dim Response As Integer
arrNotes = Split(ActiveDocument.Range, delim)
Response = MsgBox("This will split the document into " & UBound(arrNotes) + 1 & " sections.Do you wish to proceed?", 4)
If Response = 7 Then Exit Sub
For I = LBound(arrNotes) To UBound(arrNotes)
If Trim(arrNotes(I)) <> "" Then
X = X + 1
Set doc = Documents.Add
doc.Range = arrNotes(I)
doc.SaveAs ThisDocument.Path & "\" & strFilename & Format(X, "000")
doc.Close True
End If
Next I
End Sub
Sub test()
'delimiter & filename
SplitNotes "///", "Notes "
End Sub

3। तब दबायें रन VBA लागू करने के लिए बटन या F5 कुंजी दबाएँ।

4. सामने आने वाले Microsoft Word दस्तावेज़ में, कृपया आगे बढ़ने के लिए हाँ बटन पर क्लिक करें।

नोट:
(1) अपने सीमांकक को उसी के समान जोड़ना सुनिश्चित करें "///" दस्तावेज़ के उप परीक्षण में पाठ के प्रत्येक अनुभाग के बीच जिसे आप अलग करना चाहते हैं। इसके अलावा, आप बदल भी सकते हैं "///" आपकी आवश्यकता को पूरा करने के लिए किसी भी सीमांकक के लिए।
(2) आप दस्तावेज़ बदल सकते हैं "टिप्पणियाँ" आपकी आवश्यकताओं के अनुरूप उप परीक्षण में।
(3) और विभाजित दस्तावेज़ मूल फ़ाइल के साथ उसी स्थान पर सहेजे जाएंगे।
(4) आपको मूल फ़ाइल के अंत में डिलीमीटर जोड़ने की आवश्यकता नहीं है, यदि आप ऐसा करते हैं, तो विभाजन के बाद एक खाली दस्तावेज़ होगा।

यहां एक और वीबीए है जो आपको वर्ड में एक वर्ड दस्तावेज़ को कई पेजों में जल्दी से विभाजित करने में मदद करता है। कृपया इस प्रकार करें:

1। दबाएँ ऑल्ट + F11 एप्लिकेशन विंडो के लिए Microsoft Visual Basic खोलने के लिए कुंजियाँ एक साथ;

2। क्लिक करें सम्मिलित करें > मॉड्यूल, और फिर नई खुलने वाली मॉड्यूल विंडो में नीचे VBA कोड चिपकाएँ।

वीबीए: वर्ड में पेज के अनुसार दस्तावेज़ को एकाधिक दस्तावेज़ों में विभाजित करें

Sub SplitIntoPages()
Dim docMultiple As Document
Dim docSingle As Document
Dim rngPage As Range
Dim iCurrentPage As Integer
Dim iPageCount As Integer
Dim strNewFileName As String
Application.ScreenUpdating = False 'Makes the code run faster and reduces screen _
flicker a bit.
Set docMultiple = ActiveDocument 'Work on the active document _
(the one currently containing the Selection)
Set rngPage = docMultiple.Range 'instantiate the range object
iCurrentPage = 1
'get the document's page count
iPageCount = docMultiple.Content.ComputeStatistics(wdStatisticPages)
Do Until iCurrentPage > iPageCount
If iCurrentPage = iPageCount Then
rngPage.End = ActiveDocument.Range.End 'last page (there won't be a next page)
Else
'Find the beginning of the next page
'Must use the Selection object. The Range.Goto method will not work on a page
Selection.GoTo wdGoToPage, wdGoToAbsolute, iCurrentPage + 1
'Set the end of the range to the point between the pages
rngPage.End = Selection.Start
End If
rngPage.Copy 'copy the page into the Windows clipboard
Set docSingle = Documents.Add 'create a new document
docSingle.Range.Paste 'paste the clipboard contents to the new document
'remove any manual page break to prevent a second blank
docSingle.Range.Find.Execute Findtext:="^m", ReplaceWith:=""
'build a new sequentially-numbered file name based on the original multi-paged file name and path
strNewFileName = Replace(docMultiple.FullName, ".doc", "_" & Right$("000" & iCurrentPage, 4) & ".doc")
docSingle.SaveAs strNewFileName 'save the new single-paged document
iCurrentPage = iCurrentPage + 1 'move to the next page
docSingle.Close 'close the new document
rngPage.Collapse wdCollapseEnd 'go to the next page
Loop 'go to the top of the do loop
Application.ScreenUpdating = True 'restore the screen updating
'Destroy the objects.
Set docMultiple = Nothing
Set docSingle = Nothing
Set rngPage = Nothing
End Sub 

3। तब दबायें रन बटन या प्रेस F5 VBA लागू करने की कुंजी.

नोट: विभाजित दस्तावेज़ों को मूल फ़ाइल के साथ उसी स्थान पर सहेजा जाएगा।

यदि आपके पास Word के लिए Kutools स्थापित है, तो आप इसे लागू कर सकते हैं विभाजित करें वर्ड में आपकी आवश्यकता के अनुसार पेज, हेडिंग, सेक्शन ब्रेक या पेज ब्रेक के आधार पर एक दस्तावेज़ को आसानी से कई दस्तावेज़ों में विभाजित करने का कार्य।

1.Click कुटूल्स प्लस > विभाजित करें को सक्षम करने के लिए विभाजित करें सुविधा.

2. स्क्रीन में खुलने वाले स्प्लिट संवाद में, आप निम्नानुसार कार्य कर सकते हैं:

(1) से विभाजन का रास्ता चुनें द्वारा विभाजित ड्राॅप डाउन लिस्ट।
यह सुविधा 6 विभाजन तरीकों का समर्थन करती है: शीर्षक 1, पेज ब्रेक, सेक्शन ब्रेक, पेज, प्रत्येक एन पेज, और कस्टम पेज रेंज जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है:

(2) क्लिक करें ब्राउज बटन  विस्तृत विवरण देना वह गंतव्य फ़ोल्डर जिसमें आप विभाजित दस्तावेज़ों को सहेजेंगे;

(3) नए दस्तावेज़ नामों के उपसर्ग के रूप में एक कीवर्ड टाइप करें दस्तावेज़ उपसर्ग डिब्बा।

सुझाव:
(1) यदि आप वर्तमान दस्तावेज़ को विभाजित करने को निर्दिष्ट करते हैं हर एन पेज, आपको इसमें संख्या निर्दिष्ट करनी होगी हर एन पेज डिब्बा;

(2) यदि आप वर्तमान दस्तावेज़ को कस्टम पृष्ठ श्रेणियों द्वारा विभाजित करने के लिए निर्दिष्ट करते हैं, तो आपको इन कस्टम पृष्ठ श्रेणियों को अल्पविराम से अलग करके दर्ज करना होगा पेज बॉक्स, उदाहरण के लिए, बॉक्स में 1, 3-5, 12 टाइप करें।

3। दबाएं Ok बंटवारा शुरू करने के लिए बटन.

फिर वर्तमान दस्तावेज़ को निर्दिष्ट विभाजन तरीके से विभाजित किया जाता है, और नए दस्तावेज़ थोक में गंतव्य फ़ोल्डर में सहेजे जाएंगे।