एक्सेल में राइट क्लिक मेनू से एकाधिक मैक्रोज़ कैसे चलाएं?

यदि आपकी कार्यपुस्तिका में एकाधिक वीबीए मैक्रोज़ हैं, तो आपको वीबीए विंडो खोलनी चाहिए और फिर जब आपको कोड चलाने की आवश्यकता हो तो मैक्रो चुनें। इस लेख में, मैं आपके काम को और अधिक कुशल बनाने के लिए राइट क्लिक मेनू से मैक्रोज़ को चलाने के तरीके के बारे में बात करना चाहूंगा जैसा कि बाएं स्क्रीनशॉट में दिखाया गया है।

VBA कोड के साथ राइट क्लिक मेनू से एकाधिक मैक्रोज़ चलाएँ

VBA कोड के साथ राइट क्लिक मेनू से एकाधिक मैक्रोज़ चलाएँ

किसी कार्यपुस्तिका में राइट क्लिक मेनू से मैक्रो कोड चलाने के लिए, निम्नलिखित चरण आपकी सहायता कर सकते हैं, कृपया ऐसा करें:

1. नीचे छेद करें ऑल्ट + F11 कुंजी को खोलने के लिए अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक खिड़की.

2. फिर, डबल क्लिक करें यह बाएँ में परियोजना फलक, और फिर नीचे दिए गए VBA कोड को कॉपी करके रिक्त मॉड्यूल में पेस्ट करें।

Private Sub Workbook_Open()
Run "LoadMacro"
End Sub
Private Sub Workbook_Activate()
Run "LoadMacro"
End Sub
Private Sub Workbook_Deactivate()
Run "ClearMacro"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Run "ClearMacro"
ThisWorkbook.Save
End Sub

3. अभी भी में अनुप्रयोगों के लिए माइक्रोसॉफ्ट विज़ुअल बेसिक विंडो, कृपया क्लिक करें सम्मिलित करें > मॉड्यूल, और निम्नलिखित कोड को इस मॉड्यूल में पेस्ट करें।

Private Sub LoadMacro()
Dim xArrMenu As Variant
Dim xStrLine, xSreBtnName As String
Dim xObjCBCF, xObjCntrAll As CommandBarControl
Dim xObjCBCs As CommandBars
Dim xObjCBBtn As CommandBarButton
Dim xIntLine, xFNum As Integer
Dim xObjComponent As Object
Run "ClearMacro"
Set xObjCBCF = Application.CommandBars("Cell").Controls.Add(msoControlPopup, before:=1)
xObjCBCF.Caption = " Run Macro "
xObjCBCF.BeginGroup = False
For Each xObjComponent In ActiveWorkbook.VBProject.VBComponents
    If xObjComponent.Type = 1 Then
        For xIntLine = 1 To xObjComponent.CodeModule.CountOfLines
        xStrLine = xObjComponent.CodeModule.Lines(xIntLine, 1)
        xStrLine = Trim(xStrLine)
            If (InStr(xStrLine, "()") > 0) And (Left(xStrLine, 11) = "Private Sub" Or Left(xStrLine, 3) = "Sub") Then
            xSreBtnName = ""
            If "Private Sub" = Left(xStrLine, 11) Then
                xSreBtnName = Trim(Mid(xStrLine, 12, InStr(xStrLine, "()") - 12))
            ElseIf "Sub" = Left(xStrLine, 3) Then
               xSreBtnName = Trim(Mid(xStrLine, 4, InStr(xStrLine, "()") - 4))
            End If
            If xSreBtnName <> "" And xSreBtnName <> "RightClickReset" And xSreBtnName <> "LoadMacro" And xSreBtnName <> "ActionMacro" Then
                Set xObjCBBtn = xObjCBCF.Controls.Add
                With xObjCBBtn
                    .FaceId = 186
                    .Style = msoButtonIconAndCaption
                    .Caption = xSreBtnName
                    .OnAction = "ActionMacro"
                End With
            End If
            End If
        Next xIntLine
    End If
Next xObjComponent
End Sub
Private Sub ClearMacro()
On Error Resume Next
CommandBars("Cell").Controls(" Run Macro ").Delete
Err.Clear
CommandBars("Cell").Reset
End Sub
Private Sub ActionMacro()
On Error GoTo Err1
With Application
Run .CommandBars("Cell").Controls(1).Controls(.Caller(1)).Caption
End With
Exit Sub
Err1:
    MsgBox "Invalid"
End Sub

4. - कोड पेस्ट करने के बाद क्लिक करें टूल्स > संदर्भ, और एक सन्दर्भ-VBAप्रोजेक्ट संवाद बॉक्स प्रदर्शित होता है, और फिर जांचें एप्लीकेशन एक्स्टेंसिबिलिटी 5.3 के लिए माइक्रोसॉफ्ट विजुअल बेसिक में विकल्प उपलब्ध संदर्भ सूची बॉक्स, स्क्रीनशॉट देखें:

5। तब दबायें OK संवाद से बाहर निकलने के लिए, अब, आपको इस कार्यपुस्तिका को इस रूप में सहेजना चाहिए एक्सेल मैक्रो-सक्षम वर्कबुक प्रारूप, स्क्रीनशॉट देखें:

6. अंत में, कृपया कोड प्रभाव लेने के लिए कार्यपुस्तिका को पुनः प्रारंभ करें, और अब, जब आप किसी सेल पर राइट क्लिक करते हैं, तो a मैक्रो चलाएं विकल्प राइट क्लिक मेनू में डाला गया है, और आपकी कार्यपुस्तिका के सभी मैक्रोज़ निम्न स्क्रीनशॉट के रूप में सबमेनू में सूचीबद्ध हैं:

7. फिर आप कोड को केवल क्लिक करके चला सकते हैं।